Genbot Version 12 Ready

[LordGiddion]

Current File Versions:
Genbot.mac 12.30
BotCore.inc 12.33
BotCombat.inc 12.31
BotSpell.inc 12.33
BotHealer.inc 12.30
ShortCuts.inc 12.31
Personal.inc 12.30
GenbotDoc 12.10 <----- Not Current

Update 5/7/2004 11:00 PM
Bug Fixes

Update 5/6/2004 10:00 PM
Some fixes to some bugs I added today

Update 5/6/2004 4:00 PM
Added more event awarness to spell casting
Added recast pause to buffs, fail 5 casts will pause the buff recast for 15 minutes.
Selfbuff works now, if you fail to buff yourself it will retry like buff does i.e 5 times 5 seconds appart 5 fails equals 15 minute pause
Added optional Param to report buffs, Param "Queue" will caused the bot to report the status of the report queue
Added command SelfBuff This command causes the bot to cast a buff on itself, it will then monitor the buff status (rather then a timer like Buff) to determine when to recast the spell, "Buff x on Yourself" will automatically use "selfBuff" logic. The Companion ini value "selfbuff" can be used to load a list of buffs the bot will automatically maintain on itself.
Example:

Code: Select all

[spell]
SelfBuf=armor of the faithful|Resolution

This example INI entry would cause the bot to always maintain "armor of the faithful" and "Resolution" on itself, recasting if they run out or get nulified

Note: "Buff Off" will cause the bot to forget any queued rebuffs
"SelfBuff off" will cause the bot to stop maintaining self buffs
readded chainstun explained below, should chain stuns in cycle with enough pause to maximize mana
in the ini:

Code: Select all

[spell]
chainstun=color slant|color cloud
chainnuke=

This code will cause the bot to chain "color cloud" and "word of worell" (you can add as many stun spells as you want to the chain seperated by "|") each spell will be cast 1 second before the last spells duration wares off.
ChainNuke works about the same except that it doesn't do the duration wait.

Update 05/04/2004 9:00 pm
Fixed Chat Channel back to a string. Sorry about the confusion.
Fixed Buff now shouldn't error and should rebuff correctly
Fixed Genbot mode follow and Moveto
I think I fixed Behind functions
Fixed Reload (I think - sometimes gets errors I can't track down sometimes works)
Toggles now take 1/0, True/false yes/no on/off and are case insensitive.
New ini reading sub function - will be expanded later to read from other sources
New AddToggle function so you can add toggles in your personal.inc
Lots of small fixes from the board
Cmds is now case-insensitive

Hoping we are now relitivly bug free and I can go back to adding functions


Update 5/1/2004 8:00 am
Lots of fixes from the user community

Update 4/30/2004 5:00 pm
Fixed the Toggle problem
Auto heal still buggy, still trying to fix it

Update 4/30/2004 3:00 pm
More fixes, FollowMode 1 = follow should be fixed - thnx gus
Spellcasting in general, as well as SN, SNT and Buff should all be fixed now.


FYI Personal.inc in my release is stripped down to a stub I expect it to stay this way, I will not post my personal.inc and I ask that other people don't post theirs in this thread. If you must post your personal.inc please post it in a different thread (maybe in the snippetes forum) and provide support for it there.

[LordGiddion]

Genbot.mac

Code: Select all

|genbot.mac 
|Generic bot macro for any class. 
|Version 12.30
|Date:05/04/2004 9:00 pm
| 
||** 
[genbot] 
version=12.30
**||
| 

#include botcore.inc 
#include botspell.inc 
#include botcombat.inc 
#include bothealer.inc 
#include shortcuts.inc 
#include personal.inc 
#include advpath.inc 
#turbo 40 

Sub Main 
	/declare Commands[2,500] string outer
	/declare Toggles[5,50] string outer
	/declare ShortCuts[4,50] string outer
	/declare TopCommand int outer 1
	/declare TopToggle int outer 1
	/declare TopShortCut int outer 1
   
	|Determine master(s)
	|Determine if masterlist already exists - will exist if this is a reload
	/if (!${Defined[MasterList]}) {
		/if (!${Defined[Param0]}) { 
      	/echo Usage: /macro generic <Master Name1> <Master Name2>... 
      	/endmacro 
   	} 
   	/declare MasterList string global 
   }
   /if (${Defined[Param0]}) {
		|clear and rebuild master list if a list was passed
		/varset MasterList |
		/declare MasterCount int local
   	/for MasterCount 0 to ${Macro.Params}
   		/varset MasterList ${MasterList}${Param${MasterCount}}|
   	/next MasterCount
	}
	
   
    |Initialize variables in each include
   /call Init-Core 
   /call Init-Combat 
   /call Init-Spell 
   /call Init-Healer 
   /call Init-Toggles
   /call Init-Shortcuts
   /call Init-Personal 
   :MainLoop 
   /varset BreakOut 0
   /doevents 
   |Fire tasks in each Include
   /call CoreMain
   /call HealerMain
   /call SpellMain
   /call CombatMain  
   /call PersonalMain 
   /call AdvPathPoll 
   /goto :MainLoop 
/return 

[LordGiddion]

Botcore.inc

Code: Select all

|botcore.inc 
|Bot core module. 
|Version 12.33
|Date:05/07/2004 11:00 pm
| 
||** 
[botcore] 
version=12.33
**||

#chat group 
#chat tell 
#chat chat 

#Event CorpseTooFar "You are too far away to loot that corpse." 
#event FollowOff "You are no longer auto-following" 
#Event Zoned "LOADING, PLEASE WAIT..." 
#Event Appear "You appear." 
#Event Appearing "You feel yourself starting to appear." 
#Event LosingLev "You feel as if you are about to fall" 
#Event SelfEcho "[MQ2] Genbot "

Sub Init-Core   
	/declare cmds-CORE string outer Core:
	|For each command
	|/call AddCommand "Command Section" "Command Phrase" "Called Sub"
	|Command Section - where the command will be listed in response to the cmd phrase
	|Command Phrase to trigger bot - End User can change to suit prefferences
	|Called Sub - Routine to execute in response to Command Phrase
	/call AddCommand CORE accept Do-accept 
	/call AddCommand CORE reject Do-reject
	/call AddCommand CORE invite Do-invite 
	/call AddCommand CORE follow Do-follow 
	/call AddCommand CORE stop Do-stop 
	/call AddCommand CORE moveto Do-moveto 
	/call AddCommand CORE sit Do-sit 
	/call AddCommand CORE stand Do-stand 
	/call AddCommand CORE camp Do-camp 
	/call AddCommand CORE duck Do-duck 
	/call AddCommand CORE norelay Do-norelay 
	/call AddCommand CORE say Do-say 
	/call AddCommand CORE tell Do-tell 
	/call AddCommand CORE group Do-group 
	/call AddCommand CORE cmds Do-cmds
	/call AddCommand CORE target Do-target
	/call AddCommand CORE notarget Do-notarget
	/call AddCommand CORE assist Do-assist   
	/call AddCommand CORE saytarget Do-saytarget 
	/call AddCommand CORE itemcast Do-itemcast 
	/call AddCommand CORE lootup Do-lootup 
	/call AddCommand CORE anchor Do-anchor 
	/call AddCommand CORE trade Do-trade 
	/call AddCommand CORE yesres Do-yes 
	/call AddCommand CORE consent Do-consent 
	/call AddCommand CORE reportbuffs Do-reportbuffs 
	/call AddCommand CORE petattack Do-petattack 
	/call AddCommand CORE petguard Do-petguard 
	/call AddCommand CORE petback Do-petback 
	/call AddCommand CORE relay Do-relay 
	/call AddCommand CORE run Do-run 
	/call AddCommand CORE door Do-door 
	/call AddCommand CORE verbosity Do-verbosity 
	/call AddCommand CORE chatin Do-chatin 
	/call AddCommand CORE lootall Do-lootall 
	/call AddCommand CORE face Do-face 
	/call AddCommand CORE autoinv Do-autoinv 
	/call AddCommand CORE anchorradius Do-anchorradius 
	/call AddCommand CORE rmod Do-rmod 
	/call AddCommand CORE rset Do-rset 
	/call AddCommand CORE stay Do-stay 
	/call AddCommand CORE pause Do-pause 
	/call AddCommand CORE reload Do-reload 
	/call AddCommand CORE mount Do-mount 
	/call AddCommand CORE dismount Do-dismount 
	/call AddCommand CORE random Do-random 
	/call AddCommand CORE exp Do-exp 
	/call AddCommand CORE Setvar Do-Setvar 
	/call AddCommand CORE Rptvar Do-Rptvar 
	/call AddCommand CORE FollowMode Do-FollowMode 
	/call AddCommand CORE MoveToMode Do-MoveToMode
	/call AddCommand CORE afk Do-afk
	|Declare Vars
   /declare AnchorX int outer 0
   /declare AnchorY int outer 0
   /declare IsAnchored bool outer FALSE
   /declare LootTooFar int outer 0
   /declare MasterName string outer ${MasterList.Arg[1,|]}
   /declare GenLastXLoc int outer 0
   /declare GenLastYLoc int outer 0
   /declare ObstacleCheck int outer 0
   /declare RangeMin int outer 10
   /declare RangeMax int outer 12
   /declare FastRange int outer 14
   /declare FastMin int outer 6
   /declare FollowTarget string outer 
   /declare Afollow int outer 0
   /declare FollowMode int outer 1
   /declare MoveToMode int outer 1
   /declare CheckName bool outer FALSE
   /declare Relaytells bool outer TRUE
   /declare BreakOut bool outer FALSE
   /declare Combatstatus bool outer FALSE
   /declare ListenGroup bool outer FALSE
   /declare ListenChat bool outer FALSE
   /declare AttackOnAssist bool outer FALSE
   /declare BehindOnAssist bool outer FALSE
   /declare PetOnAssist bool outer FALSE
   /declare Verbosity int outer 9
   /declare ChatIn string outer Tell
   /declare ChatInChannel string outer 
   /declare IgnGroupList string outer 
   /declare ListenChan string outer 
   /declare AnchorRadius int outer 10
   /declare Supportstatus bool outer
   /declare CurrCommand string outer 
   /declare CommandParam string outer
   /declare advpath bool outer 
   /declare MountItem string outer
   /declare FaceFastini int outer
   /declare SpeedSenseini int outer
   /declare FollowDistanceini int outer
   /declare SilentFlagini int outer
   
|Timers 
   /declare SitTimer timer 

	/call LoadSetting RangeMin CORE RangeMin 10
	/call LoadSetting RangeMax CORE RangeMax 12
	/call LoadSetting FastRange CORE FastRange 14
	/call LoadSetting FastMin CORE FastMin 6
	/call LoadSetting Relaytells CORE Relaytells 1
	/call LoadSetting ListenGroup CORE ListenGroup 1
	/call LoadSetting ListenChat CORE ListenChat 1
	/call LoadSetting ListenChan CORE ListenChan 1
	/call LoadSetting AttackOnAssist CORE AttackOnAssist 0
	/call LoadSetting BehindOnAssist CORE BehindOnAssist 0
	/call LoadSetting PetOnAssist CORE PetOnAssist 0
	/call LoadSetting Verbosity CORE Verbosity 9
	/call LoadSetting ChatIn CORE ChatIn Tell
	/call LoadSetting ChatInChannel CORE ChatInChannel "Channel Name"
	/call LoadSetting MountItem CORE MountItem "Name of Bridle or Drum"
	/call LoadSetting AnchorRadius CORE AnchorRadius 6
	/call LoadSetting IgnGroupList CORE IgnGroupList duck|say|tell|group|cmds|trade|run|backstab|taunt|evade|slam|bash|kick|flyingkick|disarm|traps|puller||
	/call LoadSetting FollowMode CORE FollowMode 1
	/call LoadSetting MoveToMode CORE MoveToMode 1
	/call LoadSetting CheckName CORE CheckName 0
	/call LoadSetting FaceFastini advpath FaceFast 1
	/call LoadSetting SpeedSenseini advpath SpeedSense 15
	/call LoadSetting FollowDistanceini advpath FollowDistance 20
	/call LoadSetting SilentFlagini advpath SilentFlag 1
	
 

   /declare advpathv float local 
   /varset advpathv ${Ini[advpath.inc,advpath,version,99999]} 
   /if (${advpathv}==99999) { 
      /echo Advanced pathing NOT available. 
      /varset advpath 0 
   } else { 
   	/if (${advpathv}>=1.24) { 
      	/echo Advanced pathing v(${advpathv}) enabled. 
         /varset advpath TRUE 
         /call InitAPFVars ${FaceFastini} ${SpeedSenseini} ${FollowDistanceini} 
         /varset SilentFlag ${SilentFlagini}
      } else { 
         /echo Minimum advpath.inc v(1.24) required - you have v(${advpathv}) 
         /echo Advanced pathing found, but too old. Update it! 
         /varset advpath FALSE 
      } 
   } 
/return 

Sub CoreMain
	/if (!${Combatstatus}) {
   	/if ((!${Supportstatus})&&(!${IsAnchored})) {
			/if (${Afollow}) {
            /target ${FollowTarget} 
            /varset CommandParam ${FollowTarget}
            /call Do-moveto ${FollowTarget} 
         } 
    		/if (${advpath}) /call AdvPathPoll 
      } 
      /if (${IsAnchored}) { 
         /if (${Math.Distance[${AnchorX},${AnchorY}]}>${AnchorRadius}) { 
            /call MoveToAnchor 
         } else {
         	/if ((${SitAfterCast})&&(${Me.Standing})) /sit 
         } 
      } 
   } 
/return

Sub AddCommand(string CmdSect,string CmdPhrase,string CmdRoutine)
	/varset Commands[1,${TopCommand}] ${CmdPhrase}
	/varset Commands[2,${TopCommand}] ${CmdRoutine}
	/varcalc TopCommand ${TopCommand}+1
	/varset cmds-${CmdSect} ${cmds-${CmdSect}} ${CmdPhrase}
/return 

Sub LoadSetting(string VarName,string SectionName,string KeyName,string DefaultValue)
	/if (!${Defined[LoadFrom]}) {
		/declare LoadFrom string outer ini
	}
	/if (${LoadFrom.Equal[ini]}) {
		/declare IniValue string local
		/if (!${Defined[IniFile]}) {
			|setup ini File Reference
   		/declare IniFile string outer genbot_${Me.CleanName}.ini
		}
		/varset IniValue ${Ini[${IniFile},${SectionName},${KeyName},NOTFOUND]} 
   	/if (${IniValue.Equal[NOTFOUND]}) { 
     		/ini ${IniFile} ${SectionName} ${KeyName} ${DefaultValue}
      	/varset ${VarName}  ${DefaultValue}
   	} else {
   		/varset ${VarName}  ${IniValue}
   	}
	}

/return

Sub Event_Chat(string ChatType,string ChatSender,string ChatText)
   /if (!${ChatType.Equal[GROUP]} && !${ChatType.Equal[${ListenChan}]}&& !${ChatType.Equal[TELL]}) { 
   	/return 
   } 
   /if (${ChatType.Equal[GROUP]} && !${ListenGroup}) /return 
   /if (${ChatType.Equal[${ListenChan}]} && !${ListenChat}) /return 
   /if (${ChatType.Equal[${ListenChan}]} || ${ChatType.Equal[GROUP]}) {
   	/if (${CheckName} && ${ChatText.Arg[1].NotEqual[${Me.CleanName}]}) /return
   	/if (${CheckName}) {
   		/declare NameLength int local ${Me.CleanName.Length}
   		/varcalc NameLength ${NameLength}+1
   		/varset ChatText ${ChatText.Right[-${NameLength}]}
   	} else {
   		/if (${IgnGroupList.Find[${ChatText.Arg[1]}]}) /return
   	}
   } 
   /if (${MasterList.Find[|${ChatSender}|]}) {
   	/varset MasterName ${ChatSender}
   	/call ExecCommand "${ChatText}"
   	/return
   }
   /if (${Relaytells} && ${ChatType.Equal[TELL]}) /call ChatOut 1 ${MasterName} "${ChatSender} told me: ${ChatText}"
/return 

Sub Event_SelfEcho(string EchoText)
	/varset MasterName ${Me.CleanName}
	/varset EchoText ${EchoText.Right[-13]}
	/call ExecCommand "${EchoText}"
/return

Sub ExecCommand(string CommandText)
   /declare CommandLen int local
   /declare counter int local
   /varset CurrCommand ${CommandText.Arg[1]}
   /varcalc CommandLen ${CurrCommand.Length}+1
   /if (${CommandText.Length} > ${CommandLen}) {
   	/varset CommandParam ${CommandText.Right[-${CommandLen}]}
   } else {
   	/varset CommandParam
   }
	/for counter 1 to ${TopCommand}
		/if (${CurrCommand.Equal[${Commands[1,${counter}]}]}) {
			/call ${Commands[2,${counter}]} ${CommandParam}
		}
	/next counter
   
   /if (${Defined[Toggles]}) {
   	/for counter 1 to ${TopToggle}
   		/if (${CurrCommand.Equal[${Toggles[1,${counter}]}]}) {
   			/call SetToggle ${counter} ${CommandParam}
   		}
   	/next counter
   }
   /if (${Defined[ShortCuts]}) {
   	/for counter 1 to ${TopShortCut}
   		/if (${CurrCommand.Equal[${ShortCuts[1,${counter}]}]}) {
   			/call ShortCut ${counter} ${CommandParam}
   		}
   	/next counter
   }
/return 

Sub ChatOut(int ChatPriority,string ChatTarget,string ChatText) 
	/if (${ChatPriority}>${Verbosity}) /return
   /if (${ChatTarget.Equal[GROUP]}) { 
      /gsay ${ChatText}
      /return 
   } 
   /if (${ChatTarget.Equal[${Me.CleanName}]}) {
   	/echo ${ChatText}
   	/return
   }
   /if (${ChatIn.Equal[tell]}) { 
      /tell ${ChatTarget} ${ChatText} 
   } else /if (${ChatIn.Equal[Group]}) { 
      /gsay ${ChatText} 
   } else /if (${ChatIn.Equal[Raid]}) { 
      /rsay ${ChatText} 
   } else /if (${ChatIn.Equal[Say]}) { 
      /say ${ChatText} 
   } else /if (${ChatIn.Equal[Channel]}) { 
      /chat #${ChatInChannel} ${ChatText} 
   } else /if (${ChatIn.Equal[IRC]}) { 
      /irc ${ChatText}
   } 
/return 

Sub Detectobst 
	/if (${Math.Distance[${GenLastXLoc},${GenLastYLoc},${Me.Z}:${Me.X},${Me.Y},${Me.Z}]}<10) /call Hitobst 5  
   /varset GenLastXLoc ${Me.X} 
   /varset GenLastYLoc ${Me.Y}
/return 

Sub Hitobst(int HoldTime)
	/keypress FORWARD 
   /keypress BACK hold 
   /if (${Math.Rand[100]}>50) {
   	/call Delay 2s 
      /keypress BACK 
      /keypress RIGHT hold 
      /call Delay ${HoldTime}
      /keypress RIGHT
      /keypress FORWARD hold 
      /call Delay 2s 
      /keypress FORWARD 

   } else { 
      /call Delay 2s 
      /keypress BACK 
      /keypress LEFT hold 
      /call Delay ${HoldTime}
      /keypress LEFT 
      /keypress FORWARD hold 
      /call Delay 2s 
      /keypress FORWARD 
   } 
   /keypress LEFT 
   /keypress RIGHT
/return 

sub Loot 
   /declare counter int local 
   /declare LootSlot int local 1
   /if (${Me.Combat}) /return 
   /if (!${Target.ID}) /target corpse radius 100 
   /if (${Target.State.NotEqual[DEAD]}) /return 
   /call Rangesub
   /face 
   /varset LootTooFar 0 
   /lootn never 
   /loot 
   /varset counter 0 
   :CoreWaitLoot 
      /call Delay 5 
      /doevents 
      /varcalc counter ${counter}+1 
      /if (${BreakOut}) /goto :donelooting 
      /if (${counter}>12) /goto :donelooting 
   /if (!${Corpse.Items}) /goto :CoreWaitLoot 
   /call ChatOut 5 ${MasterName} "Looting ${Target.CleanName}." 
   :lootloop  
   	/if (${LootTooFar}) /goto :donelooting 
   	/if (!${Corpse.Items}) /goto :donelooting 
   	/doevents 
   	/itemnotify loot${LootSlot} rightmouseup
   	/call Delay 1s 
   	/varcalc LootSlot ${LootSlot}+1 
   	/doevents 
   	/if (${Cursor.ID}) /goto :donelooting
   	/if (${BreakOut}) /goto :donelooting 
   /goto :lootloop 
   :donelooting 
   /lootn always 
   /notify LootWnd DoneButton leftmouseup
/return 

sub LootAll 
   :LootAllCycle 
   /if (${Me.Combat}) /return 
   /if (!${Target.ID}) /target corpse radius 100 
   /if (!${Target.State.Equal[DEAD]}) /return  
   /call Loot
   /goto :LootAllCycle 
/return 

|RangeSub 
|Used to keep bot in combat range. 
|Usage /call Rangesub 
|Vars Used: RangeMax, RangeMin, FastRange 
|RangeSub 
|Used to keep bot in combat range. 
|Usage /call Rangesub 
|Vars Used: RangeMax, RangeMin, FastRange, FastMin 
Sub Rangesub 
   /if (!${Target.ID}) /return 
   /if (${Target.CleanName.Equal[${Me.CleanName}]}) /return 
   /if (${Me.Sitting}) /stand 
   /face fast 
   /if (${Target.Distance}>=${FastRange}) /call Fastmove 
   /if (${Target.Distance}<=${FastMin}) /call FastBack 
   /if (${Target.Distance}>${RangeMax}) /keypress FORWARD 
   /if (${Target.Distance}<${RangeMin}) /keypress BACK 
/return 

Sub Fastback 
   /varset ObstacleCheck 0 
   /varset GenLastXLoc ${Me.X}
   /varset GenLastYLoc ${Me.Y}
   :fastbackloop 
	   /doevents 
	   /if (!${Target.ID}) { 
	      /varset Combatstatus 0 
	      /Keypress BACK 
	      /if (${Me.Combat}) /attack off 
	      /return 
	   } 
	   /if (${Me.Sitting}) /stand 
	   /face fast 
	   /if (${Target.Distance}<${FastMin}) /Keypress BACK hold 
	   /if (${Target.Distance}>=${FastMin}) { 
	      	/Keypress BACK 
	      	/return 
	   	}  
   /if (${ObstacleCheck}>=8) { 
      /if ((${GenLastXLoc}==${Me.X})&&(${GenLastYLoc}==${Me.Y})) { 
      	/if (${Math.Rand[100]}>50) {
            /Keypress STRAFE_LEFT hold 
            /delay 1 
            /Keypress STRAFE_LEFT
            /return
         } else {
         	/Keypress STRAFE_RIGHT hold 
         	/delay 1 
            /Keypress STRAFE_RIGHT
            /return
         }
      } 
      /varset GenLastXLoc ${Me.X}
      /varset GenLastYLoc ${Me.Y}
   } 
   /varcalc ObstacleCheck ${ObstacleCheck}+1 
   /goto :fastbackloop 
/return 

|Fastmove 
|Called by Rangesub for when mob is more than /keypress distance away. 
|Usage: /call Fastmove 
Sub Fastmove 
   /varset ObstacleCheck 0 
   /varset GenLastXLoc ${Me.X} 
   /varset GenLastYLoc ${Me.Y} 
   :fastmoveloop 
   /doevents 
   /if (!${Target.ID}) { 
      /varset Combatstatus 0 
      /keypress FORWARD  
      /if (${Me.Combat}) /attack off  
      /return 
   } 
   /if (${Me.Sitting}) /stand  
   /face fast 
   /if (${Target.Distance}>${FastRange}) /keypress FORWARD hold 
   /if (${Target.Distance}<=${FastRange}) { 
      /keypress FORWARD 
      /return 
   } 
   /if (${ObstacleCheck}>=60) { 
      /call Detectobst 
      /varset ObstacleCheck 0 
   } 
   /if (${Target.Distance}>=${FastRange}) /varcalc ObstacleCheck ${ObstacleCheck}+1 
   /goto :fastmoveloop 
/return 

Sub MoveToAnchor 
   /varset GenLastXLoc ${Me.X} 
   /varset GenLastYLoc ${Me.Y}
   /varset ObstacleCheck 0 
   :AnchorMoveLoop 
	   /if (!${IsAnchored}) { 
	      /keypress BACK 
	      /return 
	   } 
	   /doevents 
	   /if (${Combatstatus}) { 
	      /keypress down 
	      /return 
	   } 
	   /if (${Me.Sitting}) /stand  
	   /face nolook loc ${AnchorX},${AnchorY}
	   /if (${Math.Distance[${AnchorX},${AnchorY}]}>${AnchorRadius}) /keypress FORWARD hold 
	   /if (${Math.Distance[${AnchorX},${AnchorY}]}<=${AnchorRadius}) { 
	      /keypress FORWARD   
	      /face away nolook loc ${AnchorX},${AnchorY} 
	      /return 
	   } 
	   /if (${ObstacleCheck}>=3) { 
	      /call Detectobst 
	      /varset ObstacleCheck 0 
	   } 
	   /varcalc ObstacleCheck ${ObstacleCheck}+1  
   /goto :AnchorMoveLoop 
/return 

Sub Event_CorpseTooFar 
   /call ChatOut 5 ${MasterName} "I'm not close enough to loot ${Target.CleanName}." 
   /varset LootTooFar 1 
/return 

Sub Event_Zoned 
   /varset IsAnchored 0 
   /keypress FORWARD 
/return 

Sub Event_FollowOff 
   /target clear
   /call Delay 5 
   /call ChatOut 5 ${MasterName} "Auto follow Off." 
/return 

Sub Event_timer(string TimerName,string OldValue)
   /if (${TimerName.Equal[SitTimer]}) { 
      /if (${Me.Standing}) /sit 
   } 
   /if (${TimerName.Equal[ChainStunTime]}) { 
   	/call NextStun
   }
   /if (${TimerName.Equal[BuffListAdvance]}) {
   	/declare counter int local
		/for counter 1 to ${BuffListCount}
			/varcalc BuffListTimes[${counter},1] ${BuffListTimes[${counter},1]}-5
			/if (${BuffListTimes[${counter},1]}<5) {
				/call StandardTarget "${BuffList[${counter},1]}"
				/if (${Target.CleanName.Equal[${BuffList[${counter},1]}]}) {
					/call SpellSub "${BuffList[${counter},2]}"
					/if (${Macro.Return}==0) /varset BuffListTimes[${counter},1] ${Spell[${BuffList[${counter},2]}].Duration.TotalSeconds}
					/if (${Macro.Return}==1) /varcalc BuffListTimes[${counter},2] ${BuffListTimes[${counter},2]}+1
					/if (${BuffListTimes[${counter},2]}>5) {
						/varset BuffListTimes[${counter},1] 900
						/varset BuffListTimes[${counter},2] 0
					}
				}
			}
		/next counter
		/for counter 1 to 15
			/if (${SelfBuffInt[${counter},1]}> 1) /varcalc SelfBuffInt[${counter},1] ${SelfBuffInt[${counter},1]}-5
		/next counter
		/varset BuffListAdvance 50
   }
/return 

Sub Event_Appear 
   /call ChatOut 3 ${MasterName} "I'm no longer invis." 
/return 

Sub Event_Appearing 
   /call ChatOut 3 ${MasterName} "I'm starting to appear." 
/return 

Sub Event_LosingLev 
   /call ChatOut 3 ${MasterName} "I'm losing Levitate" 
/return 

Sub StandardTarget(string TargetName)
	/if (!${Defined[TargetName]}) { 
      /assist ${MasterName} 
   } else /if (${TargetName.Length}==0) {
   	/assist ${MasterName} 
   } else /if (${TargetName.Equal[me]}) { 
      /target pc ${MasterName} 
   } else /if (${TargetName.Equal[yourself]}) { 
      /target myself 
   } else /if (${TargetName.Equal[${Me.CleanName}]}) { 
      /target myself 
   } else { 
      /target ${TargetName}
   } 
/return
		
||||||||||||Do-subs 

Sub Do-target 
   /varset Supportstatus 1 
   /call StandardTarget "${CommandParam}"
   /call ChatOut 5 ${MasterName} "My target is now ${Target.CleanName}." 
/return 

Sub Do-saytarget 
   /call ChatOut 5 ${MasterName} "my target is ${Target.CleanName}." 
/return 

Sub Do-assist(string AssistName)
   /varset Supportstatus 1 
   /if (!${Defined[AssistName]}) { 
      /assist ${MasterName} 
   } else /if (${AssistName.Equal[me]}) { 
      /assist ${MasterName} 
   } else /if (${AssistName.Equal[yourself]}) { 
      /return
   } else /if (${AssistName.Equal[${Me.CleanName}]}) { 
      /return
   } else { 
      /assist ${CommandParam}
   } 
   /call Delay 5 
   /if (!${Target.ID}) { 
      /call ChatOut 5 ${MasterName} "I failed to get a target." 
   } else { 
      /call ChatOut 5 ${MasterName} "My target is now ${Target.CleanName}."
      /if (${AttackOnAssist}) /varset Combatstatus 1 
      /if (${BehindOnAssist}) /call do-getbehind 
      /if (${PetOnAssist}) {
      	/if (${Me.Sitting}) /Stand  
		   /call Delay 5 
		   /pet attack 
		   /call Delay 5 
		   /if (${SitAfterCast} && ${Me.Standing}) /varset SitTimer ${DelayBeforeSit} 
      }
   } 
/return 

Sub Do-sit 
   /varset Afollow 0 
   /varset FollowTarget NULL
   /if ((${advpath})&&(${FollowFlag})) /call StopFunction  
   /if (${Me.Standing}) /sit
/return 

Sub Do-stand 
   /if (${Me.Sitting}) /Stand
/return 

Sub Do-notarget 
   /target clear 
/return 

Sub Do-relay 
   /varset Relaytells 1 
/return 

Sub Do-norelay 
   /varset Relaytells 0 
/return 

Sub Do-afk 
   /if (!${Defined[Param0]}) { 
      /afk 
   } else { 
      /afk ${CommandParam}
   } 
   /call ChatOut 3 ${MasterName} "Going afk." 
/return 

Sub Do-say 
   /if (!${Defined[Param0]}) { 
      /return 
   } else { 
      /say ${CommandParam} 
   } 
/return 

Sub Do-group 
   /if (!${Defined[Param0]}) { 
      /return 
   } else { 
      /g ${CommandParam} 
   } 
/return 

Sub Do-tell 
   /if (!${Defined[Param0]}) { 
      /return 
   } else { 
      /tell ${CommandParam} 
   } 
/return 

Sub Do-accept 
   /target clear 
   /invite 
/return 

Sub Do-reject 
   /target clear 
   /disband 
/return 

Sub Do-invite(string TargetName)
	/if (!${Defined[Param0]}) { 
		/assist ${MasterName}  
   } else /if (${TargetName.Equal[me]}) { 
   	/target pc ${MasterName}
   } else /if (${TargetName.Equal[yourself]}) { 
      /return
   } else /if (${TargetName.Equal[${Me.CleanName}]}) { 
      /return
   } else { 
      /target pc ${CommandParam} 
   } 
   /call ChatOut 3 ${MasterName} "Inviting ${Target.CleanName}." 
   /invite 
/return 

Sub Do-face 
   /call StandardTarget "${CommandParam}"
   /call ChatOut 5 ${MasterName} "Facing ${Target.CleanName}."
   /if (${Me.Sitting}) /Stand 
   /call Delay 5    
   /face 
/return 

Sub Do-stop 
   /dismount 
   /varset Supportstatus 0 
   /varset BreakOut 1 
   /varset LootTooFar 1 
   /varset SpellFail 1 
   /varset Afollow 0 
   /if ((${advpath})&&(${FollowFlag})) /call StopFunction 
   /varset FollowTarget NULL
   /call ChatOut 5 ${MasterName} "Stopping." 
   /keypress LEFT
   /keypress RIGHT 
   /keypress DUCK 
   /keypress DUCK 
   /target clear 
   /keypress right 
/return 

Sub Do-stay 
   /varset Afollow 0 
   /varset FollowTarget NULL
   /if ((${advpath})&&(${FollowFlag})) /call StopFunction 
   /keypress LEFT
   /keypress RIGHT
/return 

Sub Do-camp 
   /dismount 
   /varset Afollow 0 
   /if ((${advpath})&&(${FollowFlag})) /call StopFunction 
   /varset FollowTarget NULL
   /keypress LEFT
   /keypress RIGHT
   /call ChatOut 3 ${MasterName} "Camping out."
   /if (${Me.Standing}) /Sit 
   /camp desktop 
/return 

Sub Do-pause 
      /if (${advpath}) { 
         /if (!${PauseFlag}) { 
         	/call ChatOut 5 ${MasterName} "Pausing." 
      	} else { 
         	/call ChatOut 5 ${MasterName} "Unpausing." 
      	} 
      	/call PauseFunction 
      } 
/return 

Sub Do-reload 
   /call ChatOut 5 ${MasterName} "Reload initiated." 
   /mac genbot
/return 

Sub Do-duck 
   /keypress DUCK 
   /varset SpellFail 1 
   /varset CTimer 0 
/return 

Sub Do-cmds 
	/declare CommandTypes string local Core|Spell|Combat|Healer|Personal|Toggles|Shortcuts|
   /if (${Defined[Param0]} && ${CommandTypes.Find[${Param0}]}) {
   	/call ChatOut 2 ${MasterName} "${cmds-${Param0.Upper}}" 
   	/return 
  } else {
   	/call ChatOut 3 ${MasterName} "Must specify one of ${CommandTypes}" 
  }
/return 

Sub Do-moveto(string TargetName)
   /if (${Me.Sitting}) /stand
   /varset ObstacleCheck 0 
   /varset GenLastXLoc ${Me.X}
   /varset GenLastYLoc ${Me.Y}
   /if (!${Defined[TargetName]}) { 
		/assist ${MasterName}  
		/call Delay 5 
      /varset CommandParam ${Target.CleanName}
   } else /if (${TargetName.Equal[me]}) { 
   	/target ${MasterName}
   	/varset CommandParam ${Target.CleanName}
   } else /if (${TargetName.Equal[yourself]}) { 
      /return
   } else /if (${TargetName.Equal[${Me.CleanName}]}) { 
      /return
   } else { 
      /target ${CommandParam} 
   }  
   /if (!${Target.ID}) /return 
   /doevents 
   /if (${MoveToMode}==1) {
	   /if (${Supportstatus}) /return 
	   /call RangeSub 
   }
   /if (${MoveToMode}==2) {
	   /call GotoFunction "${Target.Y}" "${Target.X}" "${Target.Z}"
   }
/return 

Sub Do-trade 
   /call ChatOut 5 ${MasterName} "Clicking trade." 
   /notify TradeWnd TRDW_Trade_Button LeftMouseUp
   /call Delay 3 
/return 

Sub Do-yes 
   /call ChatOut 5 ${MasterName} "Clicking yes for res." 
   /notify ConfirmationDialogBox Yes_Button leftmouseup  
   /call Delay 3 
/return 

Sub Do-lootup 
   /if (!${Defined[Param0]}) { 
      /assist ${MasterName} 
   } else {  
      /target ${CommandParam} 
   } 
   /call Delay 5 
	/call Loot 
/return 

Sub Do-lootall 
   /if (!${Defined[Param0]}) { 
      /assist ${MasterName} 
   } else {  
      /target ${CommandParam} 
   } 
   /call Delay 5 
	/call LootAll 
/return 

Sub Do-petattack 
   /assist ${MasterName} 
   /call Delay 1s 
   /if (!${Target.ID}) /call ChatOut 5 ${MasterName} "I failed to get a target." 
   /pet attack 
/return 

Sub Do-petguard 
   /pet guard here 
/return 

Sub Do-petback 
   /pet back off 
/return 

Sub Do-anchor 
   /if (!${IsAnchored}) { 
      /varset IsAnchored 1 
      /varset AnchorX ${Me.Y} 
      /varset AnchorY ${Me.X}
      /varset Afollow 0 
   	/varset FollowTarget NULL
   	/if (${advpath} && ${FollowFlag}) /call StopFunction  
   	/keypress LEFT
   	/keypress RIGHT
      /call ChatOut 5 ${MasterName} "Created anchor at Loc: ${AnchorX},${AnchorY}." 
      /return 
   } 
   /if (${IsAnchored}) { 
     /varset IsAnchored 0 
     /call ChatOut 5 ${MasterName} "Removed Anchor." 
   } 
/return 

Sub Do-consent(string TargetName)
	/if (!${Defined[TargetName]}) { 
		/assist ${MasterName} 
		/call Delay 5 
      /varset CommandParam ${Target.CleanName}
      /consent ${Target.CleanName} 
   } else /if (${TargetName.Equal[me]}) { 
   	/call ChatOut 3 ${MasterName} "I'm giving you consent." 
      /consent ${MasterName} 
      /varset CommandParam ${MasterName} 
      /return 
   } else /if (${TargetName.Equal[yourself]}) { 
      /return
   } else /if (${TargetName.Equal[${Me.CleanName}]}) { 
      /return
   } else { 
      /consent ${CommandParam} 
   } 
   /call ChatOut 3 ${MasterName} "I gave consent to ${CommandParam}" 
/return 

Sub Do-reportbuffs  
	/if (${Defined[Param0]}) {
	   /declare myBuffs string local Buffs:
	   /declare counter int local
		/for counter 0 to 15
	   	 /if (${Me.Buff[${counter}].ID}) /varset myBuffs ${myBuffs} "${Me.Buff[${counter}]}"
	   /next counter
	   /call ChatOut 1 ${MasterName} "${myBuffs}"
	} else {
		/if (${Param0.Equal[queue]}) {
			/declare counter int local
			/for counter 1 to ${BuffListCount}
				/call ChatOut 1 ${MasterName} "Buff ${BuffList[${counter},2]} needs to be refreshed on ${BuffList[${counter},1]} in {BuffListTimes[${counter},1]} seconds."
			/next counter
		}
	}
/return 

Sub Do-run  
   /keypress ctrl+r 
/return 


Sub Do-verbosity(int NewVerbosity)
   /if (!${Defined[NewVerbosity]}) { 
      /call ChatOut 1 ${MasterName} "My Verbosity is set to ${Verbosity}." 
      /return 
   } 
   /varset Verbosity ${NewVerbosity}
   /call ChatOut 1 ${MasterName} "My Verbosity is set to ${Verbosity}." 
/return 

Sub Do-chatin 
   /if (!${Defined[Param0]}) {  
      /call ChatOut 1 ${MasterName} "My chat goes to ${ChatIn}." 
      /return 
   } 
   /varset ChatIn ${Param0}
   /call ChatOut 1 ${MasterName} "My chat goes to ${ChatIn}." 
/return 

Sub Do-rmod(int RangeMod)
   /if (!${Defined[RangeMod]}) {  
   /varcalc RangeMin ${RangeMin}+${RangeMod}
   /varcalc RangeMax ${RangeMax}+${RangeMod}
   /varcalc FastRange ${FastRange}+${RangeMod}
   /varcalc FastMin ${FastMin}+${RangeMod} 
   /call ChatOut 3 ${MasterName} "New Ranges: FastMin=${FastMin} RangeMin=${RangeMin} RangeMax=${RangeMax} FastRange=${FastRange}" 
/return 

Sub Do-rset(int NewFastMin,int NewRangeMin,int NewRangeMax,int NewFastRange)
   /if (!${Defined[NewFastMin]}) /return  
   /if (!${Defined[NewRangeMin]}) /return
   /if (!${Defined[NewRangeMax]}) /return
   /if (!${Defined[NewFastRange]}) /return
   /if (${NewFastMin}>${NewRangeMin}) /return 
   /if (${NewRangeMin}>${NewRangeMax}) /return 
   /if (${NewRangeMax}>${NewFastRange}) /return 
   /varset FastMin ${NewFastMin} 
   /varset RangeMin ${NewRangeMin}
   /varset RangeMax ${NewRangeMax}
   /varset FastRange ${NewFastRange}
   /call ChatOut 3 ${MasterName} "New Ranges: FastMin=${FastMin} RangeMin=${RangeMin} RangeMax=${RangeMax} FastRange=${FastRange}" 
/return 

Sub Do-anchorradius(int NewRadius)
   /if (!${Defined[NewRadius]}) { 
      /call ChatOut 3 ${MasterName} "My anchor radius is ${AnchorRadius}." 
   } 
   /if (${NewRadius}<3) /return 
   /varset AnchorRadius ${NewRadius}
   /call ChatOut 3 ${MasterName} "My new anchor radius is ${AnchorRadius}." 
/return 

Sub Do-follow  
   /if (${Me.Sitting}) /Stand 
   /varset IsAnchored 0
   /if (!${Defined[Param0]}) { 
         /varset FollowTarget ${MasterName} 
   } else /if (${CommandParam.Equal[me]}) { 
         /varset FollowTarget ${MasterName}
   } else /if (${CommandParam.Equal[yourself]}) { 
         /return 
   } else /if (${CommandParam.Equal[${Me.CleanName}]}) { 
         /return 
   } else { 
         /varset FollowTarget ${CommandParam}
   } 
   /target ${FollowTarget} 
	/delay 10
   /if (${FollowMode}==1) {
   	/varset Afollow 1
   }
   /if (${FollowMode}==2) { 
      /call FollowFunction "${Target.CleanName}"   
   } 
   /if (${FollowMode}==3) {
   	/follow
   }
   /if (${Target.ID}) { 
      /call ChatOut 5 ${MasterName} "I am now following ${Target.CleanName}." 
   } else { 
      /call ChatOut 5 ${MasterName} "Unable to follow ${FollowTarget}." 
      /call StopFunction 
      /varset FollowTarget NULL
   } 
/return 

Sub Do-Door 
   /doort 
   /face door 
   /keypress u 
/return 

Sub Do-autoinv 
   /autoinventory 
/return 

Sub Do-mount
   /if (${Me.Sitting}) /stand
   /cast item "${MountItem}" 
   /call ChatOut 5 ${MasterName} "Summoning my mount." 
/return 

Sub Do-dismount 
   /dismount 
   /call ChatOut 5 ${MasterName} "I got off my mount." 
/return 

Sub Do-random 
   /if (!${Defined[Param0]}) /return 
   /if (!${Defined[Param1]}) { 
      /random ${Param0}
   } else {
   	/random ${Param0} ${Param1}
   }
/return 

Sub Do-exp 
   /call ChatOut 5 ${MasterName} "I am at ${Me.PctExp} percent exp. 
/return 

Sub Do-Setvar
	/if (!${Defined[Param0]}) /return
	/declare VarLen int local
   /declare ValueLen int local
   /declare VarName string Local
   /varset VarName ${CommandParam.Arg[1]}
   /varset VarLen ${CommandParam.Length}
   /varset ValueLen ${CommandParam.Length}
   /varcalc ValueLen ${ValueLen}-${VarLen}
   /varset ${VarName} ${CommandParam.Right[${ValueLen}]}
	/call ChatOut 5 ${MasterName} "${Param0} is now equal to ${${Param0}}"
/return

Sub Do-Rptvar
	/if (!${Defined[Param0]}) /return
	/call ChatOut 5 ${MasterName} "${Param0} is equal to ${${Param0}}"
/return

Sub Do-FollowMode
	/if (!${Defined[Param0]}) /return
	/varset FollowMode ${Param0}
/return

Sub Do-MoveToMode
	/if (!${Defined[Param0]}) /return
	/varset MoveToMode ${Param0}
/return

[LordGiddion]

Botcombat.inc

Code: Select all

|botcombat.inc 
|Bot combat module. 
|Version 12.31
|Date:05/07/2004 11:00 pm
| 
||** 
[botcombat] 
version=12.31
**||
| 
#Event Enraged "has become ENRAGED" 
#Event Offrage "is no longer enraged" 
#Event FoundFloorTrap "You sense a trap in this direction" 
#Event FoundBoxTrap "You are certain that" 
#Event DisarmTrap "You have disarmed" 
#Event GettingHit " YOU for " 
#Event AttackedMiss " YOU, but " 
#Event Slash "You slash" 
#Event Hit "You Hit" 
#Event Bash "You Bash" 
#Event Pierce "You pierce" 
#Event ArcheryTooFar "Your target is too far away, get closer" 

Sub Init-Combat
	/declare cmds-COMBAT string outer Combat:
   |For each command
	|/call AddCommand "Command Section" "Command Phrase" "Called Sub"
	|Command Section - where the command will be listed in response to the cmd phrase
	|Command Phrase to trigger bot - End User can change to suit prefferences
	|Called Sub - Routine to execute in response to Command Phrase
	/call AddCommand COMBAT attack Do-attack 
	/call AddCommand COMBAT noattack Do-noattack 
	/call AddCommand COMBAT getbehind Do-getbehind 
	/call AddCommand COMBAT behind Do-behind 
	/call AddCommand COMBAT disc Do-disc 
	/call AddCommand COMBAT shield Do-shield 
	/call AddCommand COMBAT hide Do-hide 
	/call AddCommand COMBAT sneak Do-sneak 
	|Declare Variables
   /declare DoTraps bool outer FALSE
   /declare DoKick bool outer FALSE
   /declare DoBackstab bool outer FALSE
   /declare DoTaunt bool outer FALSE
   /declare DoEvade bool outer FALSE
   /declare DoSlam bool outer FALSE
   /declare DoBash bool outer FALSE
   /declare DoFlyingKick bool outer FALSE 
   /declare DoDisarm bool outer FALSE 
   /declare DoArchery bool outer FALSE 
   /declare EnrageVar bool outer FALSE 
   /declare Aggressive bool outer FALSE 
   /declare DoFrenzy bool outer FALSE
   /declare IsPuller bool outer FALSE 
   /declare AutoEngage bool outer FALSE 
   /declare AutoBehind bool outer FALSE
   /declare DoIncite bool outer FALSE
   /declare InCiteTimer timer outer
   
   /call LoadSetting DoBackstab Combat DoBackstab 0
   /call LoadSetting DoTaunt Combat DoTaunt 0
   /call LoadSetting DoEvade Combat DoEvade 0
   /call LoadSetting DoFrenzy Combat DoFrenzy 0
   /call LoadSetting DoSlam Combat DoSlam 0
   /call LoadSetting DoBash Combat DoBash 0
   /call LoadSetting DoKick Combat DoKick 0
   /call LoadSetting DoFlyingKick Combat DoFlyingKick 0
   /call LoadSetting DoDisarm Combat DoDisarm 0
   /call LoadSetting DoTraps Combat DoTraps 0
   /call LoadSetting DoArchery Combat DoArchery 0
   /call LoadSetting AutoEngage Combat AutoEngage 0
   /call LoadSetting AutoBehind Combat AutoBehind 0
   /call LoadSetting DoIncite Combat DoIncite 0
/return 

Sub CombatMain
	/call Combatcheck 
	/if ( !${Combatstatus} && ${DoTraps} ) /call TrapFinder 
   /if ( !${DoArchery} && ${Combatstatus} ) /call RangeSub 
   /if (${Combatstatus}) /call MeleeAbility 
   /if (${Me.Combat} && ${Target.ID} && !${Target.CleanName.Equal[${Me.CleanName}]} && ${AutoEngage}) {
		/varset Combatstatus 1 
   } 
/return

||||||||||||||||||||||||||||||||||||| 


|Combatcheck 
|Used to check if attack is on and should not be. 
|Usage /call Combatcheck. 
Sub Combatcheck 
   /if (${EnrageVar}) { 
      /if (${Target.ID}) { 
         /return 
      } else { 
         /varset EnrageVar 0 
         /varset Combatstatus 0 
         /attack off 
         /return 
      } 
   } 
   /if (${Supportstatus}) { 
      /if (!${Target.ID}) { 
         /call Delay 5 
         /if (!${Target.ID}) { 
            /varset Supportstatus 0 
         } 
      } 
   } 

   /if (${Combatstatus}) { 
      /if (!${Target.ID}) { 
         /call Delay 5 
         /if (!${Target.ID}) { 
            /varset Combatstatus 0 
            /varset Supportstatus 0 
            /attack off 
            /return 
         } 
      } 
      /if (${Me.Casting.ID}) /return 
      /if (${EnrageVar}) /return 
      /if ( !${DoArchery} && !${Me.Combat} ) /attack on 
      /if (${AutoBehind} && ${Math.Distance[${Math.Calc[${Target.Y}-${Math.Cos[${Target.Heading.Degrees}]}*10]},${Math.Calc[${Target.X}+${Math.Sin[${Target.Heading.Degrees}]}*10]}]}>6) /call Do-behind 
   } 
/return 

|MeleeAbility 
|Used to do melee abilities if vars are set to. 
|Usage /call MeleeAbility 
Sub MeleeAbility 
   /if (${Me.Casting.ID}) /return 
   /If (${Me.AltTimerReady}) {
   	/if (${DoSlam} && ${Me.Standing}) { 
	      /face fast
	      /doability "Slam" 
	   }
	   /if (${DoBash} && ${Me.Standing}) {
	   	/face fast
	   	/doability "Bash"
	   }
	   /if (${DoBackstab} && ${Math.Distance[${Math.Calc[${Target.Y}-${Math.Cos[${Target.Heading.Degrees}]}*10]},${Math.Calc[${Target.X}+${Math.Sin[${Target.Heading.Degrees}]}*10]}]}<15 && ${Me.Standing}) { 
	      /face fast
	      /doability "Backstab" 
	   }  
	   /if (${DoFrenzy} && ${Me.Standing}) { 
	      /face fast
	      /doability "Frenzy" 
	   } 
   }
   /if (${DoEvade} && ${Me.AbilityReady[Hide]} && ${Me.Standing}) { 
      /attack off 
      /delay 1
      /doability "Hide" 
      /attack on 
   } 
   /if (${DoTaunt} && ${Me.AbilityReady[Taunt]} && ${Me.Standing}) {
   	/doability "Taunt" 
   }
   /if (((${DoKick})&&(${Me.AbilityReady[Kick]}))&&(${Me.Standing})) { 
      /face fast
      /doability "Kick" 
   } 
   /if (${DoFlyingKick} && ${Me.AbilityReady[Flying Kick]} && ${Me.Standing}) { 
      /face fast
      /doability "Flying Kick" 
   } 
   /if (${DoDisarm} && ${Me.AbilityReady[Disarm]} && ${Me.Standing}) { 
      /face fast 
      /doability "Disarm" 
   } 
   /if (${DoArchery} && ${Me.Standing}) { 
      /face fast
      /range 
   } 
   /if (${DoIncite} && ${InCiteTimer}<=0) {
   	/face fast
   	/disc incite 
   	/varset InCiteTimer 30s
   }
/return 

Sub bscounter 
   /if (!${Target.ID}) /return 
   /if (${Me.Sitting}) /stand 
   /keypress strafe_right hold 
   :MoreCounter 
   /if (${DoBackstab} && ${Math.Distance[${Math.Calc[${Target.Y}-${Math.Cos[${Target.Heading.Degrees}]}*10]},${Math.Calc[${Target.X}+${Math.Sin[${Target.Heading.Degrees}]}*10]}]}<15 && ${Me.Standing}) { 
      /face fast
      /doability "Backstab" 
   } 
   /if (!${Target.ID}) { 
      /keypress strafe_right 
      /return 
   } 
   /if (${Target.Distance}>20) { 
      /keypress strafe_right 
      /call RangeSub 
      /return 
   } 
   /if (${Target.Distance}<4) { 
      /keypress strafe_right  
      /call RangeSub 
      /return 
   } 
   /face fast
   /if (${Me.Heading.Degrees}>=180 && ${Math.Calc[${Me.Heading.Degrees}-180]}<=${Target.Heading.Degrees} && ${Me.Heading.Degrees}>${Math.Calc[${Target.Heading.Degrees}+22.5]}) /goto :MoreCounter 
   /if (${Me.Heading.Degrees}<=180 && ${Target.Heading.Degrees}<=180 && ${Me.Heading.Degrees}>${Math.Calc[${Target.Heading.Degrees}+25]}) /goto :MoreCounter 
   /if (${Me.Heading.Degrees}>=180 && ${Target.Heading.Degrees}<=180 && ${Math.Calc[${Me.Heading.Degrees}-157.5]}<${Math.Calc[${Target.Heading.Degrees}+180]}) /goto :MoreCounter 
   /keypress strafe_right 
   /face fast
/return 

Sub bsclock 
   /if (!${Target.ID}) /return 
   /if (${Me.Sitting}) /stand 
   /keypress strafe_left hold 
   :MoreClock 
   /if (${DoBackstab} && ${Math.Distance[${Math.Calc[${Target.Y}-${Math.Cos[${Target.Heading.Degrees}]}*10]},${Math.Calc[${Target.X}+${Math.Sin[${Target.Heading.Degrees}]}*10]}]}<15 && ${Me.Standing}) { 
      /face fast
      /doability "Backstab" 
   } 
   /if (!${Target.ID}) { 
      /keypress strafe_left 
      /return 
   } 
   /if (${Target.Distance}>20) { 
      /keypress strafe_left 
      /call RangeSub 
      /return 
   } 
   /if (${Target.Distance}<4) { 
      /keypress strafe_left 
      /call RangeSub 
      /return 
   } 
   /face fast
   /if (${Target.Heading.Degrees}>=180 && ${Math.Calc[${Target.Heading.Degrees}-180]}<=${Me.Heading.Degrees} && ${Me.Heading.Degrees}<${Math.Calc[${Target.Heading.Degrees}-22.5]}) /goto :MoreClock 
   /if (${Target.Heading.Degrees}<=180 && ${Me.Heading.Degrees}<${Math.Calc[${Target.Heading.Degrees}-22.5]}) /goto :MoreClock 
   /if (${Target.Heading.Degrees}>=180 && ${Me.Heading.Degrees}<=180 && ${Math.Calc[${Me.Heading.Degrees}-22.5]}>${Math.Calc[${Target.Heading.Degrees}-360]}) /goto :MoreClock 
   /keypress strafe_left 
   /face fast
/return 

Sub CheckAggressive(string AggroText)
   /if (${Window[InventoryWindow].Open}) /return 
   /call CheckPuller 
   /if (!${Aggressive}) /return 
   /if (!${AggroText.Find[say]} && ${AggroText.NotEqual[group]} && ${AggroText.NotEqual[out of character]} && ${AggroText.NotEqual[shout]} && !${AggroText.Find[guild]} && ${Target.ID}) { 
      /if (${Target.Type.NotEqual[NPC]}) { 
         /target clear 
         /call Delay 2s 
      } 
      /if ( !${Me.Combat} && ${Target.Type.Equal[NPC]} && ${Aggressive}) { 
         /call ChatOut 5 ${MasterName} "I am being attacked by ${Target.CleanName}." 
         /call Delay 2 
         /varset Combatstatus 1 
         /attack on 
      } 
   } 
/return 

Sub CheckPuller 
   /declare AggTemp bool local 
   /if (!${IsPuller}) /return 
   /if (${Math.Distance[${AnchorX},${AnchorY}]}<=${AnchorRadius}) /return 
   /declare mobface local 
   /varset mobface ${Math.Calc[(${Me.Heading.Degrees}+180)]} 
   /varcalc mobface ${mobface}%360 
   /if (${Target.Heading.Degrees}<=${Math.Calc[${mobface}+10]} && ${Target.Heading.Degrees}>=${Math.Calc[${mobface}-10]}) { 
      /attack off 
      /varset Combatstatus 0 
      /varset AggTemp ${Aggressive} 
      /varset Aggressive 0 
      /call MoveToAnchor 
      /varset Aggressive ${AggTemp}
    } 
/return 


Sub Event_Pierce 
   /call CheckPuller 
/return 

Sub Event_Slash 
   /call CheckPuller 
/return 

Sub Event_Bash 
   /call CheckPuller 
/return 

Sub Event_Hit 
   /call CheckPuller 
/return 

Sub Event_Enraged 
   /if (${Target.ID}) { 
      /if (${Combatstatus}) { 
         /varset EnrageVar 1 
         /attack off 
      } 
      /varset EnrageVar 1 
   } 
/return 

Sub Event_Offrage 
   /if (${Target.ID}) { 
      /if (${Combatstatus}) { 
         /varset EnrageVar 0 
         /attack 

      } 
      /varset EnrageVar 0 
   } 
/return 

Sub Event_FoundBoxTrap 
   /if (${Me.AbilityReady[Disarm Traps]}) { 
      /call ChatOut 5 ${MasterName} "Trying to disarm a ${Target.CleanName} trap." 
      /doability "Disarm Traps" 
      /return 
   } 
/return 

Sub Event_FoundFloorTrap 
   /if (${Me.AbilityReady[Disarm Traps]}) {
      /call ChatOut 5 ${MasterName} "Trying to disarm a floor trap." 
      /doability "Disarm Traps" 
      /return 
   } 
/return 

Sub Event_DisarmTrap 
   /call Delay 2s 
   /call ChatOut 5 ${MasterName} "Trap disarmed." 
/return 

Sub Event_GettingHit 
   /call CheckAggressive "${Param0}"
/return 

Sub Event_AttackedMiss 
   /call CheckAggressive "${Param0}" 
/return 

Sub Event_ArcheryTooFar 
/return 

|TrapFinder 
|Used to auto sence traps when DoTraps is set to 1 
|Usage /call TrapFinder 
Sub TrapFinder 
   /if (${DoTraps} && ${Me.AbilityReady[Sense Traps]}) /doability "Sense Traps" 
   /doevents 
/return 

||||||||||||||||Command Subs 
Sub Do-behind 
   /if (!${Target.ID}) { 
      /assist ${MasterName} 
      /call Delay 5 
      } 
   :behind 
   /if (!${Target.ID}) /return 
   /doevents 
   /call RangeSub 
  | ----- Clockwise Rotate Check ----- 
   /if (!${Target.ID}) /return 
   /if (${Target.Heading.Degrees}>=180 && ${Math.Calc[${Target.Heading.Degrees}-180]}<=${Me.Heading.Degrees} && ${Me.Heading.Degrees}<${Math.Calc[${Target.Heading.Degrees}-22.5]}) /call bsclock 
   /if (!${Target.ID}) /return 
   /if (${Target.Heading.Degrees}>=180 && ${Me.Heading.Degrees}<=180 && ${Math.Calc[${Me.Heading.Degrees}-22.5]}>${Math.Calc[${Target.Heading.Degrees}-360]}) /call bscounter 
   /if (!${Target.ID}) /return 
   /if (${Target.Heading.Degrees}<=180 && ${Me.Heading.Degrees}<${Math.Calc[${Target.Heading.Degrees}-22.5]}) /call bsclock 
  | ----- Counter Clockwise Rotate Check ----- 
   /if (!${Target.ID}) /return 
   /if (${Me.Heading.Degrees}>=180 && ${Math.Calc[${Me.Heading.Degrees}-180]}<=${Target.Heading.Degrees} && ${Me.Heading.Degrees}>${Math.Calc[${Target.Heading.Degrees}+22.5]}) /call bscounter 
   /if (!${Target.ID}) /return 
   /if (${Me.Heading.Degrees}>=180 && ${Target.Heading.Degrees}<=180 && ${Math.Calc[${Me.Heading.Degrees}-157.5]}<${Math.Calc[${Target.Heading.Degrees}+180]}) /call bsclock 
   /if (!${Target.ID}) /return 
   /if (${Me.Heading.Degrees}<=180 && ${Target.Heading.Degrees}<=180 && ${Me.Heading.Degrees}>${Math.Calc[${Target.Heading.Degrees}+25]}) /call bscounter 
   /if (!${Target.ID}) /return 
   /if (${Math.Abs[${Math.Calc[${Target.Heading.Degrees}-${Me.Heading.Degrees}]}]}>30) /goto :behind 
/return 

Sub Do-getbehind 
   /varset ObstacleCheck 0 
   /varset GenLastXLoc ${Me.Y} 
   /varset GenLastYLoc ${Me.X} 
   /if (!${Target.ID}) { 
      /assist ${MasterName} 
      /call Delay 5 
   } 
   /if (${Math.Distance[${Math.Calc[${Target.Y}-${Math.Cos[${Target.Heading.Degrees}]}*10]},${Math.Calc[${Target.X}+${Math.Sin[${Target.Heading.Degrees}]}*10]}]}<3) /goto :noneed 
   /if (!${Target.ID}) /return 
   /keypress FORWARD hold 
   :gobehindloop 
   /if (${Me.State.NotEqual[STAND]}) /stand 
   /if (!${Target.ID}) { 
      /keypress FORWARD
      /return 
   } 
   /if (${ObstacleCheck}>=60) { 
      /if (${GenLastXLoc}==${Me.Y} && ${GenLastYLoc}==${Me.X}) { 
         /keypress FORWARD 
         /return 
      } 
      /varset GenLastXLoc ${Me.Y} 
      /varset GenLastYLoc ${Me.X} 
      /varset ObstacleCheck 0 
   } 
   /varcalc ObstacleCheck ${ObstacleCheck}+1  
   /doevents 
   /face nolook fast loc ${Math.Calc[${Target.Y}-${Math.Cos[${Target.Heading.Degrees}]}*10]},${Math.Calc[${Target.X}+${Math.Sin[${Target.Heading.Degrees}]}*10]} 
   /if (${Math.Distance[${Math.Calc[${Target.Y}-${Math.Cos[${Target.Heading.Degrees}]}*10]},${Math.Calc[${Target.X}+${Math.Sin[${Target.Heading.Degrees}]}*10]}]}>1) /goto :gobehindloop 
   /keypress FORWARD 
   /face fast
:noneed 
/keypress FORWARD 
/return 


Sub Do-attack 
   /varset Supportstatus 1 
   /varset Combatstatus 1 
   /if (${Me.Sitting}) /stand 
   /call StandardTarget "${CommandParam}"
   /call Delay 5
   /if (${Me.Name.Equal[${Target.CleanName}]}) { 
      /varset Combatstatus 0 
      /return 
   } 
   /call ChatOut 5 ${MasterName} "Attacking ${Target.CleanName}." 
   /if (!${DoArchery}) /attack on 
/return 

Sub Do-noattack 
   /attack off 
   /varset Combatstatus 0 
   /varset Supportstatus 0 
/return 

Sub Do-disc 
	/if (!${Defined[Param0]}) /return
  	/disc ${Param0}
/return 

Sub Do-shield
	/if ( !${Defined[Param0]} || ${Param0.Equal[me]}) { 
      /shield ${MasterName} 
   } else {
   	/shield ${CommandParam}
   } 
/return 

Sub Do-hide 
   /doability Hide 
   /call Delay 2s 
   /if (${Me.AbilityReady[Hide]}) {
   	/call ChatOut 5 ${MasterName} "I'm not hiding" 
   } else {
   	/call ChatOut 5 ${MasterName} "I am hiding."
   } 
/return 

Sub Do-sneak 
   /doability Sneak 
   /call Delay 2s 
   /if (${Me.AbilityReady[Sneak]}) {
   	/call ChatOut 5 ${MasterName} "I'm not sneaking atm" 
   } else {
   	/call ChatOut 5 ${MasterName} "I'm sneaking" 
   }
/return 

[LordGiddion]

botspell.inc

Code: Select all

|botspell.inc 
|Bot spell module. 
|Version 12.33
|Date:05/07/2004 11:00 pm
| 
||** 
[botspell] 
version=12.33
**||
| 
#event Collapse "Your gate is too unstable, and collapses." 
#event RootOff "Your Immobilize spell has worn off." 
#event NoLOS "You cannot see your target." 
#Event CastStart "You begin casting" 
#Event CastFizzle "Your spell fizzles!" 
#Event CastInterrupt "Your spell is interrupted." 
#Event CastInterrupt "Your casting has been interrupted"
#Event CastNoMana "Insufficient Mana to cast this spell" 
#Event CastTooFar "Your target is out of range, get closer!" 
#Event Recovered "You haven't recovered yet..." 
#event Recovered "Spell recovery time not yet met." 
#Event CastResist "Your target resisted " 
#Event Distracted "You are too distracted to cast a spell now!" 
#Event NoTarget "You must first select a target for this spell!" 
#Event Sitting "You must be standing to cast a spell." 
#Event NoMem "You do not seem to have that spell memorized." 
#Event Stunned "You can't cast spells while stunned!" 
#event Stunned "You *CANNOT* cast spells, you have been silenced!" 
#event MissedNote "You miss a note, bringing your song to a close!" 
#event ImmuneSlow "Your target is immune to changes in its attack speed." 
#event NoOverWrite "Your spell would not have taken hold on your target."


Sub Init-Spell 
	/declare cmds-SPELL string outer Spell:
   |For each command
	|/call AddCommand "Command Section" "Command Phrase" "Called Sub"
	|Command Section - where the command will be listed in response to the cmd phrase
	|Command Phrase to trigger bot - End User can change to suit prefferences
	|Called Sub - Routine to execute in response to Command Phrase
	/call AddCommand SPELL sn Do-sn
	/call AddCommand SPELL mana Do-mana
	/call AddCommand SPELL evac Do-evac
	/call AddCommand SPELL loadlist Do-loadlist
	/call AddCommand SPELL snt Do-snt
	/call AddCommand SPELL setlompct Do-setlompct
	/call AddCommand SPELL chainnuke Do-chainnuke
	/call AddCommand SPELL chainstun Do-chainstun
	/call AddCommand SPELL Buff Do-Buff
	/call AddCommand SPELL SelfBuff AddSelfBuff
	/call AddCommand SPELL spellgem Do-spellgem
	|/declare Vars
   /declare DefaultSpellSet string outer 
   /declare EvacSpell string outer 
   /declare DoAgain bool outer FALSE
   /declare StartCast bool outer FALSE
   /declare SpellSlot int outer 
   /declare CastTime int outer 
   /declare SitAfterCast bool outer FALSE
   /declare LastSn string outer NA  
   /declare ReportLom bool outer FALSE
   /declare LomMsg string outer
   /declare DoCanni bool outer FALSE
   /declare DoYaulp bool outer FALSE
   /declare CanniSpell string outer
   /declare YaulpSpell string outer
   /declare ChainNuke string outer
   /declare ChainStun string outer
   /declare ChainStunNum int outer
   /declare IsBard bool outer FALSE
   /declare SpellFail bool outer FALSE
   /declare DelayBeforeSit string outer 3s
   /declare Remem bool outer FALSE
   /declare BuffList[50,2] string outer
   /declare BuffListTimes[50,2] int outer 0
   /declare BuffListCount int outer 0
   /declare SelfBuffList string outer
   /declare SelfBuff[15] string outer
   /declare SelfBuffInt[15,2] int outer 0
   /declare SelfBuffCount int outer 0
   /declare SelfBuffPass int outer 0
   /declare SpellGem int outer
   /declare CTimer timer outer
   /declare OOMtimer timer outer 
   /declare LomTimer timer outer
   /declare CannTimer timer outer
   /declare CannAATimer timer outer
   /declare YaulpTimer timer outer
   /declare ChainStunTime timer outer
   /declare BuffListAdvance timer outer
   /declare SitTimer timer outer
   
   /call LoadSetting DelayBeforeSit Spell DelayBeforeSit 3s
   /call LoadSetting SpellGem Spell SpellGem 8
   /call LoadSetting SitAfterCast Spell SitAfterCast 0
   /call LoadSetting DefaultSpellSet Spell DefaultSpellSet Default
   /call LoadSetting EvacSpell Spell EvacSpell NONE
   /call LoadSetting ReportLom Spell ReportLom 0
   /call LoadSetting LomMsg Spell LomMsg "Warning I'm running low on Mana."
   /call LoadSetting CanniSpell Spell CanniSpell Canniblize
   /call LoadSetting DoCanni Spell DoCanni 0
   /call LoadSetting YaulpSpell Spell YaulpSpell yaulp
   /call LoadSetting DoYaulp Spell DoYaulp 0
   /call LoadSetting ChainStun Spell ChainStun "Your Chain Stun Spells sperated with |."
   /call LoadSetting ChainNuke Spell ChainNuke "Your Chain Nuke Spells sperated with |." 
   /call LoadSetting SelfBuffList Spell SelfBuffList "Buffs you wish to maintain of yourself sperated with |."
   /call LoadSetting IsBard Spell IsBard 0
   /call LoadSetting Remem Spell Remem 0
   /declare ArgNum int local 1
   :SelfBuffLoad
   	/if (${SelfBuffList.Arg[${ArgNum},|].Length}) {
   		/varset CommandParam ${SelfBuffList.Arg[${ArgNum},|]}
   		/call AddSelfBuff "${CommandParam}"
   	}
   	/varcalc ArgNum ${ArgNum}+1
   /if (${SelfBuffList.Arg[${ArgNum},|].Length}) /goto :SelfBuffLoad
   
/return 

Sub SpellMain
	/if (${DoCanni}) /call CheckCann
   /if (${DoYaulp}) /call CheckYaulp
   /if (${SelfBuffPass}>40) {
   	/call CheckSelfBuffs
   } else {
   	/varcalc SelfBuffPass ${SelfBuffPass}+1
   }
/return

|SpellSub 
|Main spell casting sub. 
|Used to handle all spell casting.  Auto mems spells and handles fizzles. 
|Will need to set the DefaultSpellSet var to your default spell set. 
| 
|Usage /call SpellSub "spellname" 
| 
Sub SpellSub(string SpellName)
	/if ((${Me.Casting.ID} || ${CTimer}>0) && !${IsBard}) /return 1
   /if (${SpellName.Equal[NA]}) /return 1
   /varset SpellFail 0 
   /if (${SitAfterCast}) /varset SitTimer 1140m 
   /If (${Target.Distance}>${Spell[${SpellName}].Range} && ${Spell[${SpellName}].Range}>0) { 
      /varset SpellFail 1 
      /call ChatOut 7 ${MasterName} "Too far away. " 
      /varset CTimer 0 
      /return 1  
   } 
   /if (${Me.Sitting}) /stand 
   /varset Remem 0 
   /if (!${IsBard}) { 
      /if (${Me.Moving}) { 
            /keypress FORWARD 
            /keypress BACK 
            /call Delay 1s 
      } 
      :WaitForStop 
      /doevents 
      /if (${BreakOut}) /return 
      /if (${Me.Moving}) { 
      		/echo moving
            /call Delay 1s 
            /goto :WaitForStop 
      } 
   } 
   /if (${IsBard}) /stopsong 
   |Check if character Knows the Spell requested
   /if (${Me.Book[${SpellName}]}<1) {
   	/call ChatOut 5 ${MasterName} "Don't know the spell ${SpellName} so failing to cast"
   	/goto :SpellFail
   }
   |Check if Spell is mem'd on a gem
   /if (!${Me.Gem[${SpellName}]}) {
   	/call ChatOut 3 ${MasterName} "memorizing the spell ${SpellName}"
   	/memspell ${SpellGem} "${SpellName}"
   	:MemWait 
   		/if (${BreakOut}) /return
   		/call Delay 1
   		/if (!${Me.Gem[${SpellName}]}) /goto :MemWait
   }
   /varset SpellSlot ${Me.Gem[${SpellName}]}
   /doevents 
   /if (${SpellFail}) /goto :SpellFail
   |Check if spell is ready to cast
   /if (!${Me.SpellReady[${SpellSlot}]}) {
   	/echo waiting on refresh
   	:refreshwait 
   		/if (${BreakOut}) /return
      	/call Delay 1 
      	/if (!${Me.SpellReady[${SpellSlot}]}) /goto :refreshwait 
   }
   /varset CastTime ${Spell[${SpellName}].MyCastTime.Int}
   /if (!${IsBard}) /varcalc CastTime ${CastTime}+1 
   :BeginCast 
   /varset SpellFail 0 
   /varset DoAgain 0 
   /varset StartCast 0 
   /call WaitForStart 
   :TimerLoop 
   /doevents 
   /if ((${IsBard})&&(${Combatstatus})) /call RangeSub 
   /if (${DoAgain}) /goto :BeginCast 
   /if (${SpellFail}) /goto :SpellFail
   /if (${CTimer}>0) /goto :TimerLoop 
   /if (${IsBard}) { 
      /call Delay 1 
   } else { 
      /call Delay 2 
   } 
   /doevents 
   /if (${DoAgain}) /goto :BeginCast 
   /if (${Remem}) { 
      /memspellset ${DefaultSpellSet} 
      :loadsploop 
      /call Delay 5 
      /if (${Window[SpellBookWnd].Open}) /goto :loadsploop 
   } 
	/return 0 
	:SpellFail
	/varset SpellFail 0 
   /if (${Remem}) { 
      /memspellset ${DefaultSpellSet} 
      :loadsploop 
      /call Delay 5 
      /if (${Window[SpellBookWnd].Open}) /goto :loadsploop  
   } 
   /if ((${Me.Standing})&&(${SitAfterCast})) /sit
/return 1

|WaitForStart 
|Used by SpellSub to determine when to start spell ObstacleCheck. 
Sub WaitForStart 
   /cast ${SpellSlot} 
   :StartLoop 
   /doevents 
   /if (${SpellFail}) /return 
   /if (${DoAgain}) /return 
   /if ( !${IsBard} && !${StartCast}) /goto :StartLoop 
   /varset CTimer ${Math.Calc[${CastTime}*10]} 
/return 

Sub Event_CastStart 
   /varset StartCast 1 
/return 

Sub Event_CastFizzle 
   /call Delay 2 
   /varset DoAgain 1 
/return 

Sub Event_MissedNote 
   /call Delay 2 
   /varset DoAgain 1 
/return 

Sub Event_CastInterrupt 
   /call Delay 2 
   /if (${SpellFail}) /return 
   /varset DoAgain 1 
/return 

Sub Event_Sitting 
   /stand 
   /call Delay 2 
   /varset DoAgain 1 
/return   

Sub Event_CastTooFar 
   /varset SpellFail 1 
   /call ChatOut 3 ${MasterName} "Too far away. " 
   /varset CTimer 0 
/return 

Sub Event_ImmuneSlow 
   /varset SpellFail 1 
   /call ChatOut 3 ${MasterName} "Can't Root or Snare this Target!"
   /varset CTimer 0 
/return 

Sub Event_Distracted 
   /call ChatOut 5 ${MasterName} "I can't cast. I'm too distracted. " 
   /varset SpellFail 1 
   /varset CTimer 0 
/return 

Sub Event_NoTarget 
   /varset SpellFail 1 
   /call ChatOut 3 ${MasterName} "I don't know what target to cast on. " 
   /varset CTimer 0 
/return 

Sub Event_NoOverWrite
   /varset SpellFail 1 
   /call ChatOut 3 ${MasterName} "The spell won't take hold on the target." 
   /varset CTimer 0 
/return 

Sub Event_NoMem 
   /call ChatOut 5 ${MasterName} "That spell is not memed. " 
   /varset SpellFail 1 
   /varset CTimer 0 
/return 

Sub Event_RootOff 
   /call ChatOut 5 ${MasterName} "Root has worn off. " 
/return 

Sub Event_CastNoMana 
   /if (${IsPally}) { 
      /varset SpellFail 1 
      /if (${OOMtimer}<=0) { 
         /call ChatOut 5 "${MasterName} I am OOM!" 
         /varset OOMtimer 100 
         /return 
      } 
   } 
   /if (${OOMtimer}<=0) /call ChatOut 5 ${MasterName} "OOM. Medding 13 seconds and trying again. " 
   /varset DoAgain 1 
   /if (${Me.Standing}) /sit
   /varset OOMtimer 130 
   :medingwait 
   /call Delay 1 
   /doevents 
   /if (${OOMtimer}>0) /goto :medingwait 
   /sit off 
/return 

Sub Event_Stunned 
   /call ChatOut 5 ${MasterName} "Stunned waiting 3 seconds to try again. " 
   /call Delay 3s 
   /varset DoAgain 1 
/return 

Sub Event_Recovered 
   /call Delay 2s 
   /varset DoAgain 1 
/return 

Sub Event_CastResist 
   /call ChatOut 3 ${MasterName} "${Target.CleanName} Resisted." 
   /varset SpellFail 1 
/return 

Sub Event_Collapse 
   /varset DoAgain 1 
/return 

Sub Event_NoLOS 
   /call ChatOut 10 ${MasterName} "I can't see my target. " 
   /varset SpellFail 1 
   /varset CTimer 0 
/return 

Sub Event_CastFizzle 
   /call Delay 2 
   /varset DoAgain 1 
/return 

sub CheckSelfBuffs
	/declare counter int local
	/varset SelfBuffPass 0
	/for counter 1 to ${SelfBuffCount}
		/if (!${Me.Buff[${SelfBuff[${counter}]}].ID} && ${SelfBuffInt[${counter},1]}<1) {
			/target myself
			/call SpellSub "${SelfBuff[${counter}]}"
			/if (${Macro.Return}==1 && ${SelfBuffInt[${counter},2]}<6) {
				/varset SelfBuffInt[${counter},1] 5
				/varset SelfBuffInt[${counter},2] ${SelfBuffInt[${counter},2]}+1
			}
			/if (${Macro.Return}==1 && ${SelfBuffInt[${counter},2]}>=6) {
				/varset SelfBuffInt[${counter},1] 900
				/varset SelfBuffInt[${counter},2] 0
			}
		}
	/next counter
/return

Sub CheckMana 
   /if (${LomTimer}<=0) { 
      /if (${Me.PctMana}<${LomPct}) { 
         /call ChatOut 5 ${MasterName} "${LomMsg}" 
         /varset LomTimer 2m 
      } 
   } 
/return 

Sub CheckCann 
   /if (!${Me.Moving}) { 
      /if (${Me.PctMana}<80 && ${Me.PctHPs}>=60 && ${Me.CurrentHPs}>1900 && ${CannAATimer}<=0) { 
         /alt activate 47 
         /varset CannAATimer 3m 
      } 
      /if (${Me.PctMana}<95 && ${Me.PctHPs}>=40 && ${CannTimer}<=0) { 
         /call SpellSub "${CanniSpell}" 
         /varset CannTimer 4s 
      } 
   } 
/return 

Sub CheckYaulp 
   /if (!${Me.Moving} && ${Me.PctMana}<95 && ${YaulpTimer}<=1) { 
      /call SpellSub "${YaulpSpell}" 
      /varset YaulpTimer 25s 
   } 
/return 

Sub NextStun
	/if (${BreakOut}) /return
	/if (!${Target.ID}) /return
	:JumpStunSpell
		/if (${Me.Gem[${ChainStun.Arg[${ChainStunNum},|]}]}) {
			/cast "${ChainStun.Arg[${ChainStunNum},|]}"
			/varset ChainStunTime 50
		} else {
			/varcalc ChainStunNum ${ChainStunNum}+1
			/goto :JumpStunSpell
		}
	/varcalc ChainStunNum ${ChainStunNum}+1
	/if (!${ChainStun.Arg[${ChainStunNum},|].Length}) /varset ChainStunNum 1
/return

|||||||||||||||Bot command subs 
Sub AddSelfBuff
	/if (!${Defined[Param0]}) /return
	/if (${Param0.Equal[off]}) {
		/varset SelfBuffCount 0
		/return
	}
	/varcalc SelfBuffCount ${SelfBuffCount}+1
	/varset SelfBuff[${SelfBuffCount}] ${CommandParam}
/return

Sub Do-sn(string newSpell)
   /assist ${MasterName} 
   /call Delay 10 
   /if ( !${Defined[newSpell]} && ${LastSn.Equal[NA]}) /return  
   /if (!${Defined[newSpell]}) /varset CommandParam "${LastSn}"  
   /call ChatOut 1 "${MasterName}" "Casting ${CommandParam}  on ${Target.CleanName}" 
   /call SpellSub "${CommandParam}" 
   /varset LastSn ${CommandParam}
/return 

Sub Do-mana 
	/if (!${Me.Class.CanCast}) /return 
   /declare RoundMana int local ${Math.Calc[${Math.Calc[${Me.PctMana}/5].Int}*5].Int} 
   /if (${RoundMana}==100) { 
     /call ChatOut 2 ${MasterName} "fm" 
   } else { 
     /call ChatOut 2 ${MasterName} "${RoundMana}m" 
   } 

/return 

Sub Do-loadlist(string Spellset)
   /if (!${Defined[Spellset]}) /return 
   /memspellset ${Spellset}
/return 

Sub Do-evac 
   /if (${EvacSpell.NotEqual[None]}) /call ChatOut 5 ${MasterName} "Moving to you and casting ${EvacSpell}!" 
   /call Do-moveto ${MasterName} 
   /call Delay 2s 
   /if (${EvacSpell.NotEqual[None]})  /call SpellSub "${EvacSpell}" 
/return 

Sub Do-itemcast 
	/if (!${Defined[Param0]}) /return
   /if (${Me.Sitting}) {
      /stand 
      /call Delay 3 
   } 
   /assist ${MasterName} 
   /call Delay 5 
   /varset CmdArrayNum 0 
  	/cast item "${CommandParam}" 
   /call ChatOut 3 ${MasterName} "Using ${CommandParam} on ${Target.CleanName}" 
/return 

Sub Do-snt 
	/if (!${Defined[Param0]}) /return
	/if (${Param0.Equal[on]} && ${LastSn.NotEqual[NA]}) /return
	/declare SpellNameParam string local ${Param0}
	/declare TargetName string local 
	/declare ParamCount int local 1
	/if (${Param0.Equal[on]}) {
		/varset SpellNameParam ${LastSn} 
		/goto :Do-sntTargetStart 
	}
	
	:Do-sntSpellLoop 
		/if (${Defined[Param${ParamCount}]}) {
		   /if (${Param${ParamCount}.Equal[on]}) /goto :Do-sntTargetStart 
		   /varset SpellNameParam ${SpellNameParam} ${Param${ParamCount}}
		   /varcalc ParamCount ${ParamCount}+1 
		   /goto :Do-sntSpellLoop 
		} 
	:Do-sntTargetStart 
	/varcalc ParamCount ${ParamCount}+1
	/if (!${Defined[Param${ParamCount}]}) /return
	/varset TargetName ${Param${ParamCount}} 
	/varcalc ParamCount ${ParamCount}+1 
	:Do-sntTargetLoop 
		/if (${Defined[Param${ParamCount}]}) { 
			/varset TargetName ${TargetName} ${Param${ParamCount}}
			/varcalc ParamCount ${ParamCount}+1  
			/goto :Do-sntTargetLoop 
		} 
	/echo Target SHOULD be ${TargetName}
  	/call StandardTarget "${TargetName}"
   /call Delay 5 
   /if (!${Target.ID}) { 
      /call ChatOut 5 ${MasterName} "I failed to get a target." 
      /return 
   } 
   /call SpellSub "${SpellNameParam}" 
   /if (${SitAfterCast}) /varset SitTimer ${DelayBeforeSit} 
   /varset LastSn ${CommandParam}
/return 

Sub Do-setlompct 
   /if (!${Defined[Param0]}) /return
   /varset LomPct ${Param0}
   /call ChatOut 3 ${MasterName} "I'll let you know if I get below ${LomPct} percent mana" 
/return 

Sub Do-ChainNuke
	/declare NukeNum int local 1
	/call StandardTarget "${CommandParam}"
	:ChainNukeLoop
		/if (${BreakOut}) /return
		/if (!${Target.ID}) /return
		/if (${Me.Gem[${ChainNuke.Arg[${NukeNum},|]}]}) /cast "${ChainNuke.Arg[${NukeNum},|]}"
		/varcalc NukeNum ${NukeNum}+1
		/if (!${ChainNuke.Arg[${NukeNum},|].Length}) /varset NukeNum 1
	/goto :ChainNukeLoop
/return

Sub Do-ChainStun
	/call StandardTarget "${CommandParam}"
	/if (!${Target.ID}) /return
	/varset ChainStunNum 1
	/call NextStun
/return

Sub Do-Buff
	/if (!${Defined[Param0]}) /return
	/if (${Param0.Equal[on]}) /return
	/if (${Param0.Equal[off]}) {
		/varset BuffListCount 0
		/return
	}
	/declare SpellNameParam string local ${Param0}
	/declare TargetName string local 
	/declare ParamCount int local 1
	/if (${Param0.Equal[on]}) {
		/varset SpellNameParam ${LastSn} 
		/goto :Do-BuffTargetStart 
	}
	:Do-BuffSpellLoop 
		/if (${Defined[Param${ParamCount}]}) { 
		   /if (${Param${ParamCount}.Equal[on]}) /goto :Do-BuffTargetStart 
		   /varset SpellNameParam ${SpellNameParam} ${Param${ParamCount}}
		   /varcalc ParamCount ${ParamCount}+1 
		   /goto :Do-BuffSpellLoop 
		} 
	:Do-BuffTargetStart 
	/varcalc ParamCount ${ParamCount}+1
	/if (!${Defined[Param${ParamCount}]}) /return
	/varset TargetName ${Param${ParamCount}} 
	/varcalc ParamCount ${ParamCount}+1 
	:Do-BuffTargetLoop 
		/if (${Defined[Param${ParamCount}]}) { 
			/varset TargetName ${TargetName} ${Param${ParamCount}}
			/varcalc ParamCount ${ParamCount}+1  
			/goto :Do-BuffTargetLoop 
		} 
	/if (${TargetName.Equal[yourself]} || ${TargetName.Equal[${Me.CleanName}]}) {
		/varset CommandParam ${SpellNameParam}
		/call AddSelfBuff ${CommandParam}
		/return
	}
  	/call StandardTarget "${TargetName}" 
   /call Delay 5 
   /if (!${Target.ID}) { 
      /call ChatOut 5 ${MasterName} "I failed to get a target." 
      /return 
   } 
   /call SpellSub "${SpellNameParam}"
   /if (${Macro.Return}==0) {
   	/declare NewBuff local
   	/varset NewBuff ${BuffListCount}
   	/varcalc NewBuff ${NewBuff}+1
   	/varset BuffList[${NewBuff},1] ${Target.CleanName}
   	/varset BuffList[${NewBuff},2] ${SpellNameParam}
   	/varset BuffListTimes[${NewBuff},1] ${Spell[${SpellNameParam}].Duration.TotalSeconds}
   	/varset BuffListCount ${NewBuff}
   	/varset BuffListAdvance 50
   }
   /if (${SitAfterCast}) /varset SitTimer ${DelayBeforeSit}    
/return

Sub Do-SpellGem
	/if (!${Defined[Param0]}) {
      /call ChatOut 3 ${MasterName} "I Gem ${SpellGem} when I need to mem new spells." 
      /return 
   } 
   /varset SpellGem ${Param0}
   /call ChatOut 3 ${MasterName} "I will now use Gem ${SpellGem} when I need to mem new spells."
/return

[LordGiddion]

bothealer.inc

Code: Select all

|bothealer.inc 
|Bot healer module. 
|Version 12.30
|Date:05/04/2004 9:00 pm
| 
||** 
[bothealer] 
version=12.30
**||
| 
Sub Init-Healer 
	/declare cmds-HEALER string outer Healer:
   |For each command
	|/call AddCommand "Command Section" "Command Phrase" "Called Sub"
	|Command Section - where the command will be listed in response to the cmd phrase
	|Command Phrase to trigger bot - End User can change to suit prefferences
	|Called Sub - Routine to execute in response to Command Phrase
	/call AddCommand HEALER settankheal Do-settankheal
	/call AddCommand HEALER setcasterheal Do-setcasterheal
	/call AddCommand HEALER setdefaultheal Do-setdefaultheal
	/call AddCommand HEALER heal Do-heal
	/call AddCommand HEALER setpetheal Do-setpetheal
	/call AddCommand HEALER watchtarget Do-watchtarget
	/call AddCommand HEALER resetwatch Do-resetwatch
	/call AddCommand HEALER setpatchheal Do-setpatchheal
	/call AddCommand HEALER setcasterhealpct Do-setcasterhealpct
	/call AddCommand HEALER settankhealpct Do-settankhealpct
	/call AddCommand HEALER setpethealpct Do-setpethealpct
	|declare Vars
   /declare HealPetMsg string outer 
   /declare PetPctHeal int outer 81
   /declare HealPets bool outer FALSE
   /declare PetSpell string outer 
   /declare CasterPctHeal int outer 81  
   /declare TankPctHeal int outer 51
   /declare PalGrpPct int outer 81
   /declare PalHealPct int outer 81
   /declare PalHealGrpMsg string outer 
   /declare PalHealMsg string outer 
   /declare HealCasterMsg string outer 
   /declare HealTankMsg string outer
   /declare ReportAutoHeal bool outer TRUE
   /declare PallyHealSpell string outer 
   /declare PallyGroupSpell string outer 
   /declare DefaultHealSpell string outer 
   /declare TankSpell string outer 
   /declare CasterSpell string outer 
   /declare IsHealer bool outer FALSE
   /declare IsPally bool outer FALSE
   /declare TankList string outer 
   /declare CasterList string outer 
   /declare LowHealthCheck int outer 0
   /declare CastMsgTimer1 timer outer
   /declare CastMsgTimer2 timer outer
   /declare WatchTargets[15] string outer 
   /declare WatchTargetIDs[15] int outer 0
   /declare WatchTargetCount int outer 0
   /declare WatchWaitCount int outer 0
   /declare HealTargets[21] int outer 0
   /declare PatchHealer bool outer TRUE
   /declare PatchSpell string outer 
   /declare PatchHealMsg string outer 
   
   /call LoadSetting IsHealer Healer IsHealer 0
   /call LoadSetting IsPally Healer IsPally 0
   /call LoadSetting ReportAutoHeal Healer ReportAutoHeal 1
   /call LoadSetting HealPets Healer HealPets 0
   /call LoadSetting PatchHealer Healer PatchHealer 1
   /call LoadSetting TankSpell Healer TankSpell "Name of heal spell autoheal uses on Tanks"
   /call LoadSetting CasterSpell Healer CasterSpell "Name of heal spell autoheal uses on Non Tanks"
   /call LoadSetting DefaultHealSpell Healer DefaultHealSpell "Name of Default Heal Spell"
   /call LoadSetting PetSpell Healer PetSpell "Name of Pet Heal Spell"
   /call LoadSetting PatchSpell Healer PatchSpell "Name of Patch Heal Spell"
   /call LoadSetting HealCasterMsg Healer HealCasterMsg "Healing %t"
   /call LoadSetting HealTankMsg Healer HealTankMsg "Big Heal on %t"
   /call LoadSetting HealPetMsg Healer HealPetMsg "Healing %t" 
   /call LoadSetting PatchHealMsg Healer PatchHealMsg "Patch Healing %t"
   /call LoadSetting PallyHealSpell Healer PallyHealSpell "Name of Pally Heal Spell" 
   /call LoadSetting PalHealMsg Healer PalHealMsg "Healing %t"    
   /call LoadSetting PallyGroupSpell Healer PallyGroupSpell "Name of Pally Group Heal Spell" 
   /call LoadSetting CasterPctHeal Healer CasterPctHeal 70
   /call LoadSetting TankPctHeal Healer TankPctHeal 51
   /call LoadSetting PetPctHeal Healer PetPctHeal 51
   /call LoadSetting PalGrpPct Healer PalGrpPct 81
   /call LoadSetting PalHealPct Healer PalHealPct 81
  
   /varset TankList ${Ini[${IniFile},Healer,TankList,NotFound]}
   /varset CasterList ${Ini[${IniFile},Healer,CasterList,NotFound]}
   /if (${TankList.Equal[NotFound]} && ${CasterList.Equal[NotFound]}) { 
   	/ini ${IniFile} Healer TankList "Warrior|Shadow Knight|Paladin|Monk|Beastlord|Ranger|Shaman|Berserker" 
      /ini ${IniFile} Healer CasterList "Necromancer|Wizard|Enchanter|Magician|Rogue|Druid|Cleric|Bard" 
      /varset TankList Warrior|Shadow Knight|Paladin|Monk|Beastlord|Ranger|Shaman|Berserker 
      /varset CasterList Necromancer|Wizard|Enchanter|Magician|Rogue|Druid|Cleric|Bard
   } 
/return 

Sub HealerMain
   /call CheckGrpHealth 
   /call PalGrpHealChk 
   /call PalHealChk 
/return

Sub CheckGrpHealth 
   /declare HealCount int local 0
   /declare BadIDs int local 0
   /declare SaveCombatStat int local 0
   /declare SaveCombatID int local 0 
   /declare QuickID int local 0
   /declare tempvar int local 0
   /varset BreakOut 0 
   /if (!${IsHealer}) /return 
   /if (${IsPally}) /return 
   /if (${Combatstatus}) {
   	/varset SaveCombatStat 1 
   	/varset SaveCombatID ${Target.ID} 
   }
   /varset HealCount ${Group}
   /for tempvar 1 to ${Group} 
      /varset HealTargets[${tempvar}] ${Group[${tempvar}].ID}
   /next tempvar 
   /varcalc HealCount ${HealCount}+1
   /varset HealTargets[${HealCount}] ${Me.ID}
   /if (${WatchWaitCount}>10 && ${WatchTargetCount}>0) { 
      /for tempvar 1 to ${WatchTargetCount} 
         /varcalc HealCount ${HealCount}+1 
         /varset HealTargets[${HealCount}] ${WatchTargetIDs[${tempvar}]}
      /next tempvar 
      /varset WatchWaitCount 0 
   }  
   /varcalc WatchWaitCount ${WatchWaitCount}+1 
   /for tempvar 1 to ${HealCount} 
      /if (${tempvar}>${Group} && ${Target.ID}!=${HealTargets[${tempvar}]} && ${HealTargets[${tempvar}]}!=${Me.ID}) { 
         /if (${Combatstatus}==1) /attack off 
         /target id ${HealTargets[${tempvar}]} 
         /delay 5
         /if (${Target.ID}!=${HealTargets[${tempvar}]}) { 
            /varcalc BadIDs ${BadIDs}+1 
         } 
      } 
      /doevents 
      /varset QuickID ${HealTargets[${tempvar}]}
      /if (${Spawn[${QuickID}].PctHPs}<${TankPctHeal} && ${Spawn[${QuickID}].State.NotEqual[DEAD]}) {
      	/if (${TankList.Find[${Spawn[${QuickID}].Class}]}) {
	         /if (${Spawn[${QuickID}].PctHPs}<${Math.Calc[${TankPctHeal}/2]} && ${PatchHealer}) /call PatchHeal ${QuickID} 
	         /if (${Me.Combat}) /attack off 
	         /call CastHeal ${QuickID} "${TankSpell}" "${HealTankMsg}" 
      	}
      } 
      /if (${BreakOut}) /return 
      /if ((${Spawn[${QuickID}].PctHPs}<${CasterPctHeal})&&(${Spawn[${QuickID}].State.NotEqual[DEAD]})) {
      	/if (${CasterList.Find[${Spawn[${QuickID}].Class}]}) {
	         /if ((${Spawn[${QuickID}].PctHPs}<${Math.Calc[${CasterPctHeal}/2]})&&(${PatchHealer})) /call PatchHeal ${QuickID} 
	         /if (${Me.Combat}) /attack off
	         /call CastHeal ${QuickID} "${CasterSpell}" "${HealCasterMsg}" 
      	}
      }  
      /if (${BreakOut}) /return 
      /if (${HealPets} && ${Spawn[${QuickID}].Class.PetClass} && ${Spawn[${QuickID}].Pet.ID}) { 
         /if (${Spawn[${QuickID}].Pet.PctHPs}<${PetPctHeal}) { 
            /if (${Me.Combat}) /attack off
            /call CastHeal ${QuickID} "${PetSpell}" "${HealPetMsg}"
         } 
      } 
      /doevents 
   /next tempvar 
   /if (${SaveCombatStat}) { 
      /if (${Target.ID}!=${SaveCombatID}) /target ID ${SaveCombatID} 
      /if (${Target.ID} && ${Target.Type.Equal[NPC]}) {
         /if (${Me.Sitting}) /stand 
         /attack on 
         /varset Combatstatus 1 
      } 
   } 
   /if (${BadIDs}>0) /call ResetWatchTargets 
/return 

Sub CastHeal(int TarID,string HealSpell,string castMsg)
   /if (${Me.Moving}) /return 
   /declare BadTarget local 
   /varset BadTarget 0 
   :CastHealTarget 
      /if (${TarID}==${Me.ID}) {
      	/target myself 
      } else { 
      	/if (${Target.ID}!=${TarID}) /target id ${TarID} 
      } 
      /call Delay 1 
      /if (${Target.ID}!=${TarID} && ${BadTarget}<10) { 
         /varcalc BadTarget ${BadTarget}+1 
         /goto :CastHealTarget 
      } 
   /if (${Target.ID}!=${TarID}) /return 
   /if (${Me.Sitting}) /stand 
   /if (${CastMsgTimer1}<=0) { 
      /if (${ReportAutoHeal}) /g ${castMsg}
      /varset CastMsgTimer1 50 
   } 
   /call SpellSub "${HealSpell}" 
   /if (${SitAfterCast}) /varset SitTimer ${DelayBeforeSit}  
/return 

Sub Patchheal(int TarID)
   /if (${Me.Moving}) /return 
   /if (${TarID}==${Me.ID})  /target myself 
   /if (${TarID}!=${Me.ID} && ${Target.ID}!=${TarID}) /target id ${TarID} 
   /call Delay 1 
   /if (${Me.Sitting}) /stand
   /if (${CastMsgTimer1}<=0) { 
      /if (${ReportAutoHeal}) /g ${PatchHealMsg}
      /varset CastMsgTimer1 50 
   } 
   /if (${Me.Gem[${PatchSpell}]}) /cast "${PatchSpell}" 
   /if (${SitAfterCast}) /varset SitTimer ${DelayBeforeSit} 
/return 

Sub PalGroupheal 
   /if (${Me.Sitting}) /stand
   /if (${ReportAutoHeal}) /g ${PalHealGrpMsg} 
   /call SpellSub "${PallyGroupSpell}" 
/return 

Sub PallyHeal(int TarID)
   /if (${Combatstatus}) /return 
   /if (${TarID}==${Me.ID}) /target myself 
   /if (${TarID}!=${Me.ID}) /target id ${TarID} 
   /if (${Me.Sitting}) /stand
   /if (!${Combatstatus}) /g ${PalHealMsg}
   /call SpellSub "${PallyHealSpell}" 
/return 

Sub PalGrpHealChk 
	/declare tempvar int local 1
   /if (!${IsPally}) /return 
   /if (!${IsHealer}) /return 
   /if (${Me.PctHPs}>${PalHealPct}) {
   	/varset LowHealthCheck 0 
   } else {
   	/varset LowHealthCheck 1
   }
   /for tempvar 1 to ${Group} 
	   /doevents 
	   /if ((${Group[${tempvar}].PctHPs}<${PalHealPct})&&(${Group[${tempvar}].State.NotEqual[DEAD]})) /varcalc LowHealthCheck ${LowHealthCheck}+1 
	   /if (${LowHealthCheck}>=3) {
	   	/call PalGroupheal 
	   	/return
	   }
   /next tempvar 
/return 

Sub PalHealChk 
	 /declare tempvar int local 0
   /if (!${IsPally}) /return 
   /if (!${IsHealer}) /return  
   /for tempvar 0 to ${Group} 
	   /doevents 
	   /if ((${Group[${tempvar}].PctHPs}<${PalHealPct})&&(${Group[${tempvar}].State.NotEqual[DEAD]})) /call PallyHeal ${Group[${tempvar}].ID}
   /next tempvar 
/return 

Sub ResetWatchTargets 
   /declare counter int local 
   /for counter 1 to ${WatchTargetCount} 
      /target PC ${WatchTargets[${counter}]}
      /call Delay 25 
      /if (${Target.CleanName.Equal[${WatchTargets[${counter}]}]}) { 
            /varset WatchTargetIDs[${counter}] ${Target.ID} 
      } else { 
            /call ChatOut 5 ${MasterName} "I failed to find ${WatchTargets[${counter}]} in the zone." 
      } 
   /next counter 
/return 

||||||||||||||||||Do- Subs 
Sub Do-setpetheal 
   /if (!${Defined[Param0]}) { 
      /call ChatOut 3 ${MasterName} "My pet heal is ${PetSpell}." 
      /return 
   }  
   /varset PetSpell ${CommandParam}
   /call ChatOut 3 ${MasterName} "I'll use ${PetSpell} to heal pets." 
/return 

Sub Do-setpatchheal 
   /if (!${Defined[Param0]}) {
      /call ChatOut 3 ${MasterName} "I use ${PatchSpell} for patch heals." 
      /return 
   } 
   /varset PatchSpell ${CommandParam} 
   /call ChatOut 3 ${MasterName} "I'll use ${PatchSpell} for patch heals now." 
/return 

Sub Do-settankheal 
   /if (!${Defined[Param0]}) {
      /call ChatOut 3 ${MasterName} "My tank heal is ${TankSpell}"
      /return 
   } 
   /varset TankSpell ${CommandParam} 
   /call ChatOut 3 ${MasterName} "I'll use ${TankSpell} to heal tanks." 
/return 

Sub Do-setdefaultheal 
   /if (!${Defined[Param0]}) {
      /call ChatOut 3 ${MasterName} "I usualy heal with ${DefaultHealSpell}." 
      /return 
   } 
   /varset DefaultHealSpell ${CommandParam}
   /call ChatOut 3 ${MasterName} "I'll start using ${DefaultHealSpell}." 
/return 

Sub Do-setcasterheal 
   /if (!${Defined[Param0]}) {
      /call ChatOut 3 ${MasterName} "I heal non tanks with ${CasterSpell}." 
      /return 
   } 
   /varset CasterSpell ${CommandParam} 
   /call ChatOut 3 ${MasterName} "I'll start using ${CasterSpell} on non tanks." 
/return 

Sub Do-heal 
   /call StandardTarget "${CommandParam}"
   /if (!${Target.ID}) { 
   	/target pc ${MasterName} 
   } else {
   	/if (${Target.Type.Equal[NPC]}) /target pc ${MasterName}     	 
   }
   /call ChatOut 3 ${MasterName} "Casting ${DefaultHealSpell} on ${Target.CleanName}." 
   /call SpellSub "${DefaultHealSpell}" 
   /if (${SitAfterCast}) /varset SitTimer ${DelayBeforeSit} 
/return 

Sub Do-watchtarget 
   /if (${String[${Param0}].Equal[off]}) { 
      /varset WatchTargetCount 0 
      /return 
   } 
   /target clear
   /call delay 5
   /call StandardTarget "${CommandParam}"
   /call Delay 25 
   /if (${Target.ID}) { 
      /varcalc WatchTargetCount ${WatchTargetCount}+1 
      /varset WatchTargets[${WatchTargetCount}] ${Target.CleanName}
      /varset WatchTargetIDs[${WatchTargetCount}] ${Target.ID} 
      /call ChatOut 3 ${MasterName} "Now watching the health of ${Target.CleanName}."
   } else { 
      /call ChatOut 3 ${MasterName} "Who did you want me to watch?" 
   } 
/return 

Sub Do-resetwatch 
   /call ResetWatchTargets 
/return 

Sub Do-setcasterhealpct
	/if (!${Defined[Param0]}) {
      /call ChatOut 3 ${MasterName} "I heal non tanks at ${CasterPctHeal} %." 
      /return 
   } 
   /varset CasterPctHeal ${Param0} 
   /call ChatOut 3 ${MasterName} "I heal non tanks at ${CasterPctHeal} %." 
/return

Sub Do-settankhealpct
	/if (!${Defined[Param0]}) {
      /call ChatOut 3 ${MasterName} "I heal tanks at ${TankPctHeal} %." 
      /return 
   } 
   /varset TankPctHeal ${Param0} 
   /call ChatOut 3 ${MasterName} "I heal tanks at ${TankPctHeal} %." 
/return

Sub Do-setpethealpct
	/if (!${Defined[Param0]}) {
      /call ChatOut 3 ${MasterName} "I heal pets at ${PetPctHeal} %." 
      /return 
   } 
   /varset PetPctHeal ${Param0} 
   /call ChatOut 3 ${MasterName} "I heal pets at ${PetPctHeal} %." 
/return

[LordGiddion]

shortcuts.inc

Code: Select all

|shortcuts.inc 
|Module for linking Custom Commands to Character spells and items
|Includes Variable Toggling function as well
|Version 12.31
|Date:05/07/2004 11:00 pm
| 
||** 
[shortcuts] 
version=12.31
**||

Sub Init-Toggles
	/declare cmds-TOGGLES string outer Toggles:
	|For each Variable that has a TRUE/FALSE State
	|Each Command can be toggled by 1/0, TRUE/FALSE, On/Off, Yes/No
	|/call AddToggle Command PhraseOff PhraseOn Variable Type
	|Command to force Toggle - End User change change to suit prefferences
	|PhraseOff returned by the bot when value is FALSE
	|PhraseOn returned by the bot when value is TRUE
	|Variable to be changed by the command
	| Type TRUE Command will return Variable State when no Param Present
   | Type FALSE Command Will Toggle Variable State when no Param Present
   /call AddToggle aona "I will Not Attack when Assisting." "I will Attack when Assisting." AttackOnAssist TRUE
   /call AddToggle bona "I won't move behind on assist." "I will move behind on assist." BehindOnAssist TRUE
   /call AddToggle petona "I won't send pet in on assist." "I will send pet in on assist." PetOnAssist TRUE
   /call AddToggle ListenChat "I will ignore Chat" "I will listen in Chat." ListenChat TRUE
   /call AddToggle listengroup "I will ignore Group Chat." "I will listen in Group Chat." ListenGroup TRUE
   /call AddToggle kick "Auto Kick is now off." "Auto Kick is now on." DoKick FALSE
   /call AddToggle flyingkick "Auto FlyingKick is now off." "Auto FlyingKick is now on." DoFlyingKick FALSE
   /call AddToggle disarm "Auto Disarm is now off." "Auto Disarm is now on." DoDisarm FALSE
   /call AddToggle traps "I will not detect for traps." "I will detect for traps." DoTraps FALSE
   /call AddToggle taunt "Auto Taunt is now off." "Auto Taunt is now on." DoTaunt FALSE
   /call AddToggle backstab "Auto Backstab is now off." "Auto Backstab is now on." DoBackstab FALSE
   /call AddToggle frenzy "Auto Frenzy is now off." "Auto Frenzy is now on." DoFrenzy FALSE
   /call AddToggle evade "Auto Evade is now off." "Auto Evade is now on." DoEvade FALSE
   /call AddToggle slam "Auto Slam is now off." "Auto Slam is now on." DoSlam FALSE
   /call AddToggle bash "Auto Bash is now off." "Auto Bash is now on." DoBash FALSE
   /call AddToggle beagg "Aggressive is set to off. " "Aggressive is set to on." Aggressive TRUE
   /call AddToggle puller "I'm not the puller." "I'm the puller." IsPuller TRUE
   /call AddToggle autoengage "I will not engage when attack is on." "I will engage when attack is on." AutoEngage TRUE
   /call AddToggle archery "Archery is set to off." "Archery is set to on." DoArchery TRUE
   /call AddToggle aftercastsit "I will no longer sit after casting." "I will now sit after casting." SitAfterCast FALSE
   /call AddToggle autoheal "Let me know when people need heals." "I'll watch for heals." IsHealer TRUE
   /call AddToggle autohealpets "I will not heal the pets." "I will heal the pets." HealPets TRUE
   /call AddToggle patchheal "I'm not a patch Healer." "I'm a patch Healer." PatchHealer TRUE
   /call AddToggle reportlom "I won't tell you when I'm low on Mana." "I'll let you know when I'm low on Mana." reportlom FALSE
   /call AddToggle autobehind "I won't position myself behind the mob." "I will position myself behind the mob." AutoBehind FALSE
   /call AddToggle incite "I won't use the incite discipline when in combat." "I will use the incite discipline when in combat." DoIncite FALSE
   /call AddToggle yaulp "I won't Yaulp for mana." "I will Yaulp for mana." DoYaulp TRUE
   /call AddToggle canni "I won't eat myself for mana." "I will eat myself for mana." DoCanni TRUE
   /call AddToggle Checkname "I will respond to all commands." "I will only respond to commands that are addressed to me." CheckName TRUE
   /call AddToggle Remem "I won't remem my spellset after casting." "I will remem my spellset after casting." Remem TRUE
/return

Sub AddToggle(string commandText,string OffText,string OnText,string VarName,bool ToggleType)
	/varcalc TopToggle ${TopToggle}+1
	/varset Toggles[1,${TopToggle}] ${commandText}
	/varset Toggles[2,${TopToggle}] ${OffText}
	/varset Toggles[3,${TopToggle}] ${OnText}
	/varset Toggles[4,${TopToggle}] ${VarName}
	/varset Toggles[5,${TopToggle}] ${ToggleType}
	/varset cmds-TOGGLES ${cmds-TOGGLES} ${commandText}
/return

Sub Init-Shortcuts
	/declare cmds-SHORTCUTS string outer Shortcuts:
	/declare Shortcutlist string local
	/declare ArgNum int local 0
	/declare Short string local 0
	/declare SectionNum int local 0
	/declare SectionLabel string local 0
	/declare SetType int local 0
	/declare Targeted bool local False
	
	/for SectionNum 1 to 8  
		/if (${SectionNum}==1) {
			/varset SectionLabel shortcut spells
			/varset SetType 1
			/varset Targeted TRUE
		}
		/if (${SectionNum}==2) {
			/varset SectionLabel shortcut Items
			/varset SetType 2
			/varset Targeted TRUE
		}
		/if (${SectionNum}==3) {
			/varset SectionLabel shortcut AA
			/varset SetType 3
			/varset Targeted TRUE
		}
		/if (${SectionNum}==4) {
			/varset SectionLabel Shortcut Disc
			/varset SetType 4
			/varset Targeted TRUE
		}
		/if (${SectionNum}==5) {
			/varset SectionLabel shortcut notarget Spells
			/varset SetType 1
			/varset Targeted FALSE
		}
		/if (${SectionNum}==6) {
			/varset SectionLabel shortcut notarget items
			/varset SetType 2
			/varset Targeted FALSE
		}
		/if (${SectionNum}==7) {
			/varset SectionLabel shortcut noTarget AA
			/varset SetType 3
			/varset Targeted FALSE
		}
		/if (${SectionNum}==8) {
			/varset SectionLabel shortcut noTarget Disc
			/varset SetType 4
			/varset Targeted FALSE
		}
		/varset ArgNum 1
		/varset Shortcutlist ${Ini[${IniFile},${SectionLabel},-1,NULL]}
		/if (${Shortcutlist.NotEqual[NULL]}) {
			:shortcuts
			/if (${Shortcutlist.Arg[${ArgNum},|].Length}) {
				/varcalc TopShortCut ${TopShortCut}+1
				/varset Short ${Shortcutlist.Arg[${ArgNum},|]}
				|add Command
				/varset cmds-SHORTCUTS ${cmds-SHORTCUTS} ${Short}
				/varset ShortCuts[1,${TopShortCut}] ${Short}
				|Add Spell Command Fires
				/varset ShortCuts[2,${TopShortCut}] ${Ini[${IniFile},${SectionLabel},${Short},NA]}
				|Set To True for Targeted Spell
				/Varset ShortCuts[3,${TopShortCut}] ${Targeted}
				|Set to Type 1 For Spell
				/Varset ShortCuts[4,${TopShortCut}] ${SetType}
				/varcalc ArgNum ${ArgNum}+1
				/goto :shortcuts
			}
		} 
	/next SectionNum
/return

Sub SetToggle(int ToggleNum,string newValue)
	/if (!${Defined[newValue]} && ${Toggles[5,${ToggleNum}]}) {
		/if (${${Toggles[4,${ToggleNum}]}}) {
			/call ChatOut 9 ${MasterName} "${Toggles[3,${ToggleNum}]}"
		} else {
			/Call ChatOut 9 ${MasterName} "${Toggles[2,${ToggleNum}]}"
		}
		/return
	}
	/if ( !${Defined[newValue]} && !${Toggles[5,${ToggleNum}]}) {
		/declare newValue Local
		/if (${${Toggles[4,${ToggleNum}]}}) {
			/varset newValue 0
		} else {
			/varset newValue 1
		}
	}
	/if (${newValue.Equal[True]} || ${newValue.Equal[On]} || ${newValue.Equal[1]} || ${newValue.Equal[yes]}) {
		/varset ${Toggles[4,${ToggleNum}]} 1
	} else {
		/varset ${Toggles[4,${ToggleNum}]} 0
	}
	
	/if (${${Toggles[4,${ToggleNum}]}}) {
		/call ChatOut 9 ${MasterName} "${Toggles[3,${ToggleNum}]}"
	} else {
		/Call ChatOut 9 ${MasterName} "${Toggles[2,${ToggleNum}]}"
	}
/return

Sub ShortCut(int ShortcutNum)
	/declare CastText local
	/declare ArgNum Local
	/declare Targeting int local 0
	/varset ArgNum 1
	/if (${ShortCuts[3,${ShortcutNum}]}) {
		/target clear
		/call StandardTarget "${CommandParam}"
		:targetCheck
			/if (${BreakOut}) /return
			/call delay 1
			/varcalc Targeting ${Targeting}+1
			/if (${Targeting}>15) /return
			/if (!${Target.ID}) /goto :targetCheck
	}
	:ShortCutCast
		/varset CastText ${ShortCuts[2,${ShortcutNum}].Arg[${ArgNum},|]}
		/if (${ShortCuts[4,${ShortcutNum}]}==1) /call Spellsub "${CastText}"
		/if (${ShortCuts[4,${ShortcutNum}]}==2) /cast item "${CastText}"
		/if (${ShortCuts[4,${ShortcutNum}]}==3) /alt activate "${CastText}"
		/if (${ShortCuts[4,${ShortcutNum}]}==4) /disc "${CastText}"
		/varcalc ArgNum ${ArgNum}+1
	/if (${ShortCuts[2,${ShortcutNum}].Arg[${ArgNum},|].Length}) /goto :ShortCutCast
	/if (${SitAfterCast}) /varset SitTimer ${DelayBeforeSit}  
/return

[LordGiddion]

personal.inc

Code: Select all

|personal.inc 
|Personal commands module example. 
|Version 12.30
|Date:05/04/2004 9:00 pm
| 
||** 
[personal] 
version=12.30
**||
|Define your personal Events Here
|#Event EExample "Explain it to me again" 


Sub Init-Personal
	/declare cmds-PERSONAL string outer Personal:
   |For each command
	|/call AddCommand "Command Section" "Command Phrase" "Called Sub"
	|Command Section - where the command will be listed in response to the cmd phrase
	|Called Sub - Routine to execute in response to Command Phrase
   |/call AddCommand PERSONAL command subroutine
   |Command Phrase to trigger bot - End User can change to suit prefferences
	|For each Variable that has a TRUE/FALSE State
	|Each Command can be toggled by 1/0, TRUE/FALSE, On/Off, Yes/No
	|/call AddToggle Command "PhraseOff" "PhraseOn" Variable Type
	|Command to force Toggle - End User change change to suit prefferences
	|PhraseOff returned by the bot when value is FALSE
	|PhraseOn returned by the bot when value is TRUE
	|Variable to be changed by the command
	| Type TRUE Command will return Variable State when no Param Present
   | Type FALSE Command Will Toggle Variable State when no Param Present
   |/call AddToggle PerToggle "I will not do it anymore" "I will do it now" MyToggle TRUE
	|Declare you variables here and Set their Defaults
	|/declare PersonalValue string outer
	|/Declare AnotherValue int outer default
	|INI Values 
	|/call LoadSetting PersonalVar Personal Personalkey Default
/return 

|Things that you want to happen every loop through the macro go in this sub. 
Sub PersonalMain 
	|/Call MyExampleSub
	|/if (${AnotherValue}) /call ConditionalExample
/return 

|Add your own Event and and other subroutines here

|Sub Event_EExample 
|	Some Event Code
|/return

|Sub MyExampleSub 
| Some Code activate every loop of the code
|/return

|Sub CommandFunction
|	Some Code that will run every time CommandName is activated
|/return

|sub ConditionalExample
|	Some Code that will run everytime "AnotherValue" is true
|/return

[LordGiddion]

GenbotDoc.txt

Code: Select all

|GenbotDoc.txt 
|Manual for the Generic bot macro
|Version 12.10
|Date:04/28/2004 8:00 pm
| 
||** 
[genbotDoc] 
version=12.10
**||
| 

Welcome to Genbot, probably the easiest way to 2 box or to multibox multiple characters in Everquest.

To start genbot you execute /macro genbot <mastername> with <mastername> being the name of the character that will be in control of the Bot.

By default your Bot will respond to any command the master character /tells him.

By changing the values of ListenGroup, ListenChat or sending the commands listenGroup, listenChat you can start the Bot listening for command sent either in Group or in a Chat Channel. The Bot will still only respond to characters on it's list of Masters but will do it these other channels.

Additionally if you have the IRC plugin propperly set up on your system the bot can listen in an IRC channel for commands.

By default the Bot will respond to it's Master in Tells but the INI value ChatIn or by sending the command ChatIn the bot can respond in tells, group, channel or IRC. (IRC requires functional IRC Plugin)

The first time you run Genbot on a character the macro will create a default INI file you probably want to start the macro and /endmacro it the first time so that you check/modify the INI settings.

Explination of commands your bot will understand
Core:
	afk Will cause the bot to turn on /afk you can also send a message you want the bot to put on the afk line

   accept Cause the bot to accept the current group invite
 
	reject Cause the bot to reject the current group invite

	invite Cause the bot to invite it's current target to group
 
	follow Causes the Bot to Follow the master or his designated target (see FollowMode)
 
	stop Forces the bot to stop what ever it's doing

	moveto commands the bot to move, options are ME, a location, or to a target (see MoveToMode)

	sit Makes the Bot sit

	stand Makes the Stand

	camp Causes the bot to camp out

	duck Commands the bot to duck

	norelay Stops the Bot from repeating tells to it's master

	say Commands the bot to /say what you tell it to

	tell Commands the bot to /tell what you tell it to first part of the command parameters should be the tell target

	group Commands the bot to /gsay what you tell it to

	cmds Causes the bot to return a list of available commands

	target Causes the bot to change it's target, the params can be Me (targets master) Yourself (bot targets itself) or by Target name

	notarget Causes the bot to clear it's target

	assist Causes the Bot to Assist the master, how the bot acts when assisting is controlled by toggles later in the docs

	saytarget The Bot will tell you what it's currently Targeting

	itemcast Causes the bot to trigger the specified Item
 
	lootup Commands the bot to loot the current Target if it's a corpse
 
	anchor Causes the bot to remember it's current location and return there between fights

	trade Commands the Bot to hit the Trade button in a trade window

	yesres Commands the bot to hit Yes on a confrim box

	consent Commands the bot to give consent

	reportbuffs Causes the Bot to tell it's master a list of currently active buffs

	petattack Commands the Bot to execute it's /pet attack command

	petguard Commands the Bot to execute it's /pet guard command

	petback Commands the Bot to execute it's /pet back command
	
	relay Starts the bot resending tells to it's master

	run Causes the Bot to Toggle the run setting

	door Causes the bot to attempt to open the closest door

	verbosity Changes what level chat the bot actual sends to the master

	chatin Changes what channel the bot will use for replying to the master

	lootall Causes the bot to attempt to loot all corpses arround it

	face Causes the Bot to face it's current Target

	autoinv Commands the Bot to execute it's /autoinv command

	anchorradius Sets how close the Bot must be to it's achor location before it stops moving

	rmod causes the bot to change relative distances in combat

	rset Changes the range settings the Bot uses for combat
 
	stay Causes the bot to stop following

	pause Pauses the advanced follow command

	reload Causes the bot to re-init the macro

	mount Causes the Bot to get on to it's mount

	dismount Causes the Bot to /Dismount

	random Causes the Bot to /ran 

	exp Commands the Bot to Reply with it's current Exp percent

	Setvar Sets a Var to new setting

	Rptvar Commands the Bot to Reply with the current value of a variable
	
	FollowMode Sets what how the bot Follows 1 = is Combat mode, 2 = AdvPathFollow, 3 = EQ's /follow
	
	MoveToMode Sets how the bot movesto 1 = is noraml Genbot Anchor type, 2 = AdvPathGoto
	
	CheckName if set to true bot will only respond to commands in group or chat if the command is preceeded with <botname>

Combat:	
	attack Commands the Bot to start attacking
	
	noattack Commands the Bot to Stop attacking
   
	getbehind Commands the Bot to move behind the specified Target

	behind Commands the Bot to move behind it's current Target
 
	disc Commands the Bot to fire the specified /Disc

	shield Commands the Bot to /shield it's master

	hide Commands the Bot to use it's Hide ability

	sneak Commands the Bot to use it's Sneak ability
	 
Spell:
	sn Commands the Bot to cast the specified spell on master's current Target

	mana Commands the Bot to reply with it's current Mana

	evac Commands the Bot to move to it's master and cast it's evac spell
	
	loadlist Commands the Bot to load a spell list

	snt Commands the Bot to cast <spell> ON <target>

	setlompct Sets what level of mana the bot conciders Low Mana for reporting 

	chainnuke Commands the Bot to start chaining Nukes on <target>

	chainstun Commands the Bot to start chaining Stuns on <target>

	Buff Commands the Bot to cast buff <spell> ON <target>, Bot will remember the Buff and Target and will automatically refresh it
	
	SpellGem This sets the Spell gem that the bot will use when required to memorize a new spell.
	
Healer:
	settankheal Set what spell the Bot uses to heal Tanks

	setcasterheal Set what spell the Bot uses to heal Casters

	setdefaultheal Set what spell the Bot uses to for the heal command

	heal Commands the Bot to heal <target>

	setpetheal Set what spell the Bot uses to heal Pets

	watchtarget Causes the bot to monitor the hit points of <target> Needs to have autoheal on if target should be healed

	resetwatch Causes the Bot to reaquire the ID's of it's targets, good to execute after zoning

	setpatchheal Set what spell the Bot uses to Patch heal
 
	setcasterhealpct Set what HP level a caster should be down to for the Bot to fire it's heal

	settankhealpct Set what HP level a Tank should be down to for the Bot to fire it's heal

	setpethealpct Set what HP level a Pet should be down to for the Bot to fire it's heal

Toggles:
	listengroup Controls if the bot will listen for commands in the group Channel
  
	aona Controls if the bot will attack when ordered to assist
   	
	bona Controls if the bot will attempt to attack from behind when ordered to assist
   	
	petona Controls if the bot will send in it's pet when ordered to assist
   	
	ListenChat Controls if the bot will listen for commands in the Chat Channel
   	
	kick Controls if the bot will use kick during fighting
   	
	flyingkick  Controls if the bot will use flyingkick during fighting
   	
	disarm  Controls if the bot will use Disarm during fighting
   	
	traps  Controls if the bot will attempt to find and disarm traps
   	
	taunt  Controls if the bot will use Taunt during fighting
   	
	backstab Controls if the bot will use backstab during fighting
   	
	frenzy  Controls if the bot will use frenzy during fighting
   	
	evade  Controls if the bot will use Hide during fighting
   	
	slam  Controls if the bot will use Slam during fighting
   	
	bash  Controls if the bot will use Bash during fighting
   	
	beagg Controls if the bot will automatically fight back when attacked
   	
	puller Controls if the bot will return to it's anchor point when attacked
   	
	autoengage Controls if the bot will close and engage when in combat
   	
	archery   Controls if the bot will use archery during fighting
   	
	aftercastsit   Controls if the bot will sit after casting spells
   	
	autoheal Controls if the bot will automatically use heals on group and watch targets
   	
	autohealpets  Controls if the bot will automatically use heals on pets

	patchheal Controls if the bot will automatically patch heal targets below half their heal percent 

	reportlom Controls if the bot will automatically report when it's Low on Mana

	autobehind Controls if the bot will automatically attempt to fight behind all targets during combat   

	incite Controls if the bot will use incite during fighting

	yaulp Controls if the bot will automatically use Yaulp when low on Mana

	canni Controls if the bot will automatically use Canninbalize when low on Mana

[newb-n-training]

You sir ... are my new hero

Can't wait to try this out !!

[fez_ajer]

Gid,

Here's the stuff folks were working on from the old thread:

(editing as I go)

botcombat.inc (262,267,293,475)

Code: Select all

/face [color=red]fast[/color]

botcombat.inc (472)

Code: Select all

/face nolook [color=red]fast[/color] loc ${Math.Calc[${Target.Y}-${Math.Cos[${Target.Heading.Degrees}]}*10]},${Math.Calc[${Target.X}+${Math.Sin[${Target.Heading.Degrees}]}*10]} 

botcore.inc (298)

Code: Select all

/if (${CheckName} && ${ChatText.Arg[1].NotEqual[${Me.CleanName}]}[color=red])[/color] /return

botcore.inc (304)

Code: Select all

/if [color=red]([/color]${IgnGroupList.Find[${ChatText.Arg[1]}]}[color=red])[/color] /return

botcore.inc (342)

Code: Select all

/for counter [color=red]1[/color] to ${TopShortCut}

botcore.inc (481,489)

Code: Select all

/keypress [color=red]BACK[/color]

botcore.inc (524,532)

Code: Select all

/keypress [color=red]FORWARD[/color]

botcore.inc (530)

Code: Select all

/if (${Target.Distance}>${FastRange}) /keypress [color=red]FORWARD[/color] hold

botcore.inc (599)

Code: Select all

         /varcalc BuffList[color=red][[/color]${counter},3[color=red]][/color] ${BuffList[color=red][[/color]${counter},3[color=red]][/color]}-1 
         /if (${BuffList[color=red][[/color]${counter},3[color=red]][/color]}<5) { 
            /call StandardTarget "${BuffList[color=red][[/color]${counter},1[color=darkred]][/color]}" 
            /if (${Target.CleanName.Equal[${BuffList[color=red][[/color]${counter},1[color=red]][/color]}]}) { 
               /call SpellSub "${BuffList[color=red][[/color]${counter},2[color=red]][/color]}" 
               /if (${Macro.Return}==0) /varset BuffList[color=red][[/color]${counter},3[color=red]][/color] ${Spell[${BuffList[color=red][[/color]${counter},2[color=red]][/color]}].Duration.TotalSeconds} 
            } 
         } 

botcore.inc (963) - (remove extra $)

Code: Select all

/varcat myBuffs " ${Me.Buff[${[color=red]$[/color]counter}]}"

botcore.inc (1039,1048)

Code: Select all

/target [color=red]${[/color]FollowTarget[color=red]}[/color]

botcore.inc (1041) - (keep consistant with 1 or 0)

Code: Select all

/varset Afollow [color=red]1[/color]

bothealer.inc (338) - (Current sub fuxxored)

Code: Select all

Sub PalHealChk 
   /declare tempvar int local 1 
   /if (!${IsPally}) /return 
   /if (!${IsHealer}) /return 
   /for tempvar 1 to ${Group} 
      /doevents 
      /if ((${Group[${tempvar}].PctHPs}<${PalHealPct})&&(${Group[${tempvar}].State.NotEqual[DEAD]})) /call PallyHeal ${Group[${tempvar}].ID} 
   /next tempvar 
/return 

botspell.inc (not in code :)

Code: Select all

#event RecoveryTime "Spell recovery time not yet met."
 . . .
Sub Event_RecoveryTime
   /call Delay 2
   /varset DoAgain 1
/return

botspell.inc (433) - (is changing target necessary? check for caster)

Code: Select all

Sub Do-mana 
   /if (!${Me.CanCast}) /return
   |/target myself 
   /call ChatOut 2 ${MasterName} "${Me.PctMana}m" 
   |/press esc 
/return 

That's all I see right now.

On another note, in ResetWatchTargets (and elsewhere) I'm seeing references to arrays using parens rather than square braces. Is this allowed? One of the bits above corrected that, but now that I'm seeing it in more places I'm wondering which is correct.

[Rassilon]

I got this to loadup fine. I issue the command: /tell bot cmds core (or any of them) and it tells me: NULL. I need to add something?
1. /tell bot attack doesn't do anything.
2. anchor "says" its created an anchor but after fighting it doesn't return to anchor.
3. Using a healer botted and it isn't healing.
4. It isn't facing the mob and following it and attacking.

Not sure of anything else, thats as far as I have gotten. I'm using the newest version u have posted and the newest advpath.inc/txt. Also I'm using the latest MQ2 release.

Thanks

[wassup]

Must be an issue with commands.

I started by just trying to get the boxed character to follow me. /tell <charname> follow results in a blank stare :)

Tired now, I will look at helping with debugging this tomorrow.

[Badger999]

Code: Select all

Sub Do-FollowMode 
  /if ([color=red]![/color]${Defined[Param0]}) /return
  /varset FollowMode ${Param0}
/return

Sub Do-MoveToMode
  /if ([color=red]![/color]${Defined[Param0]) /return 
  /varset MoveToMode ${Param0} 
/return

[LordGiddion]

fez_ajer:
Some of your fixes were already in 12.21 of botcore.
added /declare tempvar int local 0 to pallyHeal to fix but THAT array is the only 1 that starts at 0 so that the bot checks it's own health.
No arrays can't use () must be [] thought I caught em all

all:
Bot was taking some commands last night but this moring I see some stuff I left in while testing that would have disbaled some of the stuff I tested as working. Guess I was more tired the I thought last night. I'm posting the changes from fez_ajer and removed some of testing code. But concider this untested code. Let me feed my son and myself and then I'll take some time to do some testing with multiple bots.