spellbook.mac - provides spell memorization / forgetting

[DeathSpiral]

The following mac was designed to be #include'd by other macros. Quite simply, it can memorize and forget any spell that you have. When memorizing / forgetting a spell, the functions won't return until memorization is complete. IE, you can do the following:

Code: Select all

/call MemorizeSpell "Gate" 1
/stand

and you don't have to worry about standing interrupting your spell memorizing. If there is a spell already in the gem, it forgets it for you. Obviously enough, this is old-ui only. The following functions are provided:

• ForgetSpellByName - should be fairly obvious, provide it with the name of a spell and it will forget it. EG: /call ForgetSpellByName "Gate"
• ForgetSpellByNumber - again, fairly obvious. Provide it with the # of the spell gem you want it to forget. EG: /call ForgetSpellByNumber 3
• MemorizeSpell - Memorizes any of your spells. Doesn't even bother if a) you already have it memorized or b) you don't have it. Takes two arguments; the name of the spell to memorize and the slot to put it in. EG: /call MemorizeSpell "Minor Healing" 4
• MousetoSpellGem - moves the mouse to the appropriate spell gem (used internally)
• MousetoSpellSlot - moves the mouse to the appropriate spell slot (used internally)

With that being said, here we go!
spellbook.mac

Code: Select all

|** - spellbook.mac -
 **
 ** This macro is an include for other macros.  It deals with memorizing
 ** and forgetting spells.
 **|

| This function forgets a memorized spell by its spell name
sub ForgetSpellByName
   /if "$char(gem,"$p0")"=="NULL" /goto :EndForgetSpellByName
   /call ForgetSpellByNumber $char(gem,"$p0")
   :EndForgetSpellByName
/return

| This function forgets a memorized spell by gem #
sub ForgetSpellByNumber
   /echo FSBN called with p0 $p0
   /varset l0 $mouse(x)
   /varset l1 $mouse(y)

   /call MousetoSpellGem $p0
|   /delay 2
   /click right

   :WaitForGemFreeInForgetSpellByNumber
      /doevents
      /if "$char(gem,$p0)"!="NULL" /goto :WaitForGemFreeInForgetSpellByNumber

   /mouseto $l0 $l1
/return

| This function takes two arguments; the name of the spell to memorize and the
| spell gem to put it in
sub MemorizeSpell
   | Make sure we don't already have the spell memorized!
   /if "$char(gem,"$p0")"!="NULL" /return
   | Make sure we have the spell!
   /if "$char(book,"$p0")"=="NULL" /return

   /varset l0 $mouse(x)
   /varset l1 $mouse(y)

   | Spell book # is $l9.  Spell book page is $l8.  Spell slot is $l7.
   | Page layout is $l6
   /varset l9 $int($char(book,"$p0")-1)
   /varset l8 $int($l9\5+1)
   /varset l7 $int($l9%5)
   /varset l6 $l8

   :GetPageLayout
      /if n $l6>6 /varsub l6 6
      /if n $l6>6 /goto :GetPageLayout

   /book $l8

   | In case we need to open our spell book...
   /delay 3

   /if n $l6==1 /call MousetoSpellSlot 1 $int($l8%2) $l7
   /if n $l6==2 /call MousetoSpellSlot 2 $int($l8%2) $l7
   /if n $l6==3 /call MousetoSpellSlot 3 $int($l8%2) $l7
   /if n $l6==4 /call MousetoSpellSlot 3 $int($l8%2) $l7
   /if n $l6==5 /call MousetoSpellSlot 3 $int($l8%2) $l7
   /if n $l6==6 /call MousetoSpellSlot 4 $int($l8%2) $l7

   /delay 1

   /click left
   /delay 2

   /call MousetoSpellGem $p1

   /call ForgetSpellByNumber $p1

   /click left

   | Wait for the spell to finish memorizing
   :WaitToFinishMemorizingSpell
      /doevents
      /if "$char(gem,$p1)"=="NULL" /goto :WaitToFinishMemorizingSpell

   /mouseto $l0 $l1
/return

| Moves your mouse to the appropriate spellgem
sub MousetoSpellGem
   /varcalc l0 $int($p0-1)*38+27
   /mouseto 104 $l0
/return

| Moves your mouse to the appropriate spell slot for the given layout
|  $p0: layout $p1: even/odd (0/1) $p2: spell slot
sub MousetoSpellSlot
   /if n $p0==1 /goto :Layout1InMousetoSpellslot
   /if n $p0==2 /goto :Layout2InMousetoSpellslot
   /if n $p0==3 /goto :Layout3InMousetoSpellslot
   /if n $p0==4 /goto :Layout4InMousetoSpellslot

   :Layout1InMousetoSpellslot
      /if n $p2==0 /mouseto 202 66
      /if n $p2==1 /mouseto 280 60
      /if n $p2==2 /mouseto 280 128
      /if n $p2==3 /mouseto 202 184
      /if n $p2==4 /mouseto 280 195
      /goto :CheckRightPageInMousetoSpellslot

   :Layout2InMousetoSpellslot
      /if n $p2==0 /mouseto 200 59
      /if n $p2==1 /mouseto 276 88
      /if n $p2==2 /mouseto 200 127
      /if n $p2==3 /mouseto 276 161
      /if n $p2==4 /mouseto 200 194
      /goto :CheckRightPageInMousetoSpellslot

   :Layout3InMousetoSpellslot
      /if n $p2==0 /mouseto 191 63
      /if n $p2==1 /mouseto 284 63
      /if n $p2==2 /mouseto 238 136
      /if n $p2==3 /mouseto 191 189
      /if n $p2==4 /mouseto 284 189
      /goto :CheckRightPageInMousetoSpellslot

   :Layout4InMousetoSpellslot
      /if n $p2==0 /mouseto 242 61
      /if n $p2==1 /mouseto 193 124
      /if n $p2==2 /mouseto 281 124
      /if n $p2==3 /mouseto 202 193
      /if n $p2==4 /mouseto 267 193
      /goto :CheckRightPageInMousetoSpellslot

   :CheckRightPageInMousetoSpellslot
      /if n $p1==0 /mouseto + 161 +0
/return

[Genoius]

this works? would rawk if it does! what version of MQ? the latest IRC version i am guessing, cuz this is the first I have heard of it

---Genoius---

[DeathSpiral]

this works? would rawk if it does! what version of MQ? the latest IRC version i am guessing, cuz this is the first I have heard of it

Yes, this works. I believe $char(book,xxx) and $char(gem,xxx) were introduced in the 20020905 release. However, I'm getting the impression that there either wasn't a big announcement of the feature or many people missed it. :)

[gingertips]

aye they were announced, but its great to see someone has done this - will prove very useful - thanks!

[rizwank]

I need testers and peoples opinions.

will be included on the next CVS if it works fine.

[Gengis]

Great for running after a death

[macrotoon]

This could prove very useful if used with another macro like memspelltype.mac

Something of the sorts

/macro memspelltype guildraid

or

/macro memspelltype undeadhunt

Or a number of things.

Have another macro to include this one.

I see lots of potential here!

Great work DeathSpiral!

If i get around to a macro to include with this I'll post it.

[Nuad]

OH NOOoooo... now i have to improve my Druid.mac even more with some all purpose spell memming commands...

[rizwank]

macrotoon, that would be very much apprecaited, if you would make that macro

remember to /delay between loadings.

[eq_freak]

Awesome :)

Will have to include this in my bot as soon as I have time to fiddle with it.

[ap50]

*EDIT* Moved to it's own thread: http://macroquest2.com/phpBB2/viewtopic.php?p=5297

[Mutter]

AGain, cant get this to work i use the following code:

/press m
/delay 8
/call MemorizeSpell "Suffocating Sphere" 1
/call MemorizeSpell "Minor Shielding" 2
/call MemorizeSpell "Juli's Animation" 3
/stand

Tried without the /press M

I am baffeled.

[eqaddict]

This does not work for me either and I am at working looking it over. On a first pass it seems that

Code: Select all

   /if "$char(gem,"$p0")"!="NULL" /return 

is incorrect as $char(gem,XXX) returns a number and not a string..

maybe this would fix the problem

Code: Select all

   /if n $char(gem,"$p0")!=0 /return 

will try later tonite.

CONFIRMED... replace the above line in memorizespell with the one I provided to fix the problem

-eqA

[SingleServing]

If you cast a spell that takes 2 seconds to cast and 7 seconds to refresh after you cast the spell the macro will be paused for 7 seconds allowing the spell to refresh and not cast another spell when in reality it should only pause if the same spell were instructed to be cast again. Also, if a spell is instructed to /call cast "spell" and has not refrshed yet the function will skip the spell instead of waiting until it refreshes then attempts a recast just like the fizzle event does.

I hope this makes sense, I am very tired.

[eqaddict]

Actually, no I dont get it (

--EqA