Jewelry Crafting Macro from 1 to 250 (Version 2.2) 8/3/04

[shadowman33]

Ok, the macro starts ok, and it buys the electrum bar and the lapis lazul then tries the combine. Every time I run the macro it gets to that point then says [MQ2] EL Recipie not found.

I had to expirement and got the recipie to show up in list,but for some reason the macro does not find it.

even tried changing the first recipie to Electrum Malachite Bracelet. Changed the jc.mac and jc.ini but still get same error in macro. Can not find recipie.

[shadowman33]

just found what i did wrong. Originally i had placed the .inc files in the macro folder before remembering to make a common directory. Well when i moved the .inc files into it, I didn't notice that I had move the jc.ini file in there as well. Sorry bout that, problem fixed.

[shadowman33]

little over 4 hours went from 0 to 250 for under 30k.

[Nerun]

So theoretically this could be made to go to 300 jeweling skill...

[aChallenged1]

No, no theory involved, just the addition of the lines of code to buy and combine and sell the things needed to go from 250 to 300.

Find the best recipes and figure out how to add them in and you're on your way.

[fantum409]

I couldn't find a recipe that will allow me to get past 279 with vendor bought components (282 if you go to thurgadin and buy velium). But here is a minor mod of Override's macro, that will take you to 279 buying from rilwind in AS. Also modified the delay in it so it can go a bit faster. Delay setting (DelayMult) is now in 10th of a sec with 2 as default. Kudos to Override on this nice macro.

Code: Select all

| 
| jc.mac
| Takes you from 1 to 250 in Jewelry Crafting
| Version 2.5
| Date: September 14, 2004
|
| Please be sure to get the lastest updates at http://www.soc-music.com/mq2/
|
| Before are the settings you need to change for you.
| This Macro can take you up to 250 in Jewelry Crafting.
| SkillMaxWanted can be change to what skill you want to stop at.
| MerchantName is which merchant you are at.
| You will need to change the DelayMult to higher if you are laggy, this
|   number will be multiplied to the default delay.
|
| This Macro works best in the Abysmal Sea since all the components are there.
| You WILL need to be next to the merchant in order for this to work.
| Also, be sure you have a lot of money on you to go from 1 to 250.
|
| Requirements:
| You will need a Jewelry Kit (in the last slot).
|
| Disclaimer:
| Code was used from other programers also from the MQ Forums.
| 


#event CombineError "#*#There was no place to put that#*#" 
#event CombineError "#*#You cannot combine these items in this container type!#*#" 
#event CombineError "#*#did not accept these items#*#" 
#include common/sell.inc
#include common/buy.inc
#include common/packs.inc
#include common/cleanpacks.inc

Sub Main 
    /declare OldSkill int outer
    /declare SkillMaxWanted int outer
    /declare PackCode string outer 
    /declare Component[10] string outer 
    /declare i int outer
    /declare MerchantName string Outer
    /declare BarItem item outer
    /declare GemItem item outer
    /declare CombItemName string outer
    /declare ItemTo string outer
    /declare EndingVar int outer
    /declare Levelname int outer
    /declare DelayMult int outer
    /varset OldSkill ${Me.Skill[Jewelry Making]}

| ************************************************
| *   Change these settings to what you want.    *
| ************************************************

    /varset SkillMaxWanted 279
    /varset MerchantName "Rilwind Sitnai"
    /varset DelayMult 2


| ************************************************
| ************************************************

    :start
    /echo Jewelry Crafting is at ${Me.Skill[Jewelry Making]}

    /if (${Me.Skill[Jewelry Making]}>=${SkillMaxWanted}) {
      /echo Jewelry Making is at ${SkillMaxWanted}. Quitting!
      /endmacro
    }

    /if (${Me.Skill[Jewelry Making]}>=276 && ${Me.Skill[Jewelry Making]}<279) {
      /varset BarItem "platinum bar"
      /varset GemItem "ruby"
      /varset CombItemName "PRV"
      /varset ItemTo "Platinum Ruby Veil"
    }

    /if (${Me.Skill[Jewelry Making]}>=250 && ${Me.Skill[Jewelry Making]}<276) {
      /varset BarItem "platinum bar"
      /varset GemItem "sapphire"
      /varset CombItemName "SPN"
      /varset ItemTo "Sapphire Platinum Necklace"
    }

    /if (${Me.Skill[Jewelry Making]}>=220 && ${Me.Skill[Jewelry Making]}<250) {
      /varset BarItem "platinum bar"
      /varset GemItem "jade"
      /varset CombItemName "PJ"
      /varset ItemTo "Jaded Platinum Ring"
    }

    /if (${Me.Skill[Jewelry Making]}>=202 && ${Me.Skill[Jewelry Making]}<220) {
      /varset BarItem "platinum bar"
      /varset GemItem "lapis lazuli"
      /varset CombItemName "PLL"
      /varset ItemTo "Platinum Lapis Lazuli Necklace"
    }

    /if (${Me.Skill[Jewelry Making]}>=191 && ${Me.Skill[Jewelry Making]}<202) {
      /varset BarItem "gold bar"
      /varset GemItem "fire emerald"
      /varset CombItemName "GFE"
      /varset ItemTo "Fire Emerald Golden Bracelet"
    }

    /if (${Me.Skill[Jewelry Making]}>=183 && ${Me.Skill[Jewelry Making]}<191) {
      /varset BarItem "gold bar"
      /varset GemItem "star ruby"
      /varset CombItemName "GSA"
      /varset ItemTo "Golden Star Ruby Ring"
    }

    /if (${Me.Skill[Jewelry Making]}>=183 && ${Me.Skill[Jewelry Making]}<191) {
      /varset BarItem "gold bar"
      /varset GemItem "opal"
      /varset CombItemName "GO"
      /varset ItemTo "Golden Opal Amulet"
    }

    /if (${Me.Skill[Jewelry Making]}>=172 && ${Me.Skill[Jewelry Making]}<183) {
      /varset BarItem "gold bar"
      /varset GemItem "topaz"
      /varset CombItemName "GT"
      /varset ItemTo "Golden Topaz Earring"
    }

    /if (${Me.Skill[Jewelry Making]}>=146 && ${Me.Skill[Jewelry Making]}<172) {
      /varset BarItem "gold bar"
      /varset GemItem "amber"
      /varset CombItemName "GA"
      /varset ItemTo "Golden Amber Earring"
    }

    /if (${Me.Skill[Jewelry Making]}>=100 && ${Me.Skill[Jewelry Making]}<146) {
      /varset BarItem "gold bar"
      /varset GemItem "malachite"
      /varset CombItemName "GM"
      /varset ItemTo "Gold Malachite Bracelet"
    }

    /if (${Me.Skill[Jewelry Making]}>=76 && ${Me.Skill[Jewelry Making]}<100) {
      /varset BarItem "electrum bar"
      /varset GemItem "amber"
      /varset CombItemName "EA"
      /varset ItemTo "Electrum Amber Earring"
    }

    /if (${Me.Skill[Jewelry Making]}<76) {
      /varset BarItem "electrum bar"
      /varset GemItem "lapis lazuli"
      /varset CombItemName "EL"
      /varset ItemTo "Electrum Lapis Lazuli Earring"
    }

    /varset EndingVar 1
    /target ${MerchantName}
    /face
    /nomodkey /click right target
    /call OpenPacks
    /delay ${Math.Calc[${DelayMult}*2]}
    /call Sell ${BarItem}
    /delay ${Math.Calc[${DelayMult}*1]}
    /call Sell ${GemItem}
    /delay ${Math.Calc[${DelayMult}*1]}
    /call Buy ${BarItem} 20
    /delay ${Math.Calc[${DelayMult}*1]}
    /call Buy ${GemItem} 20
    /delay ${Math.Calc[${DelayMult}*1]}
    /nomodkey /notify MerchantWnd DoneButton leftmouseup
    /call ClosePacks
    /call OpenPacks
    /delay ${Math.Calc[${DelayMult}*2]}


    /call readIni "${CombItemName}" 
    :Begin 
       /if (${EndingVar}==1) /call ClearCursor 
       /for i 1 to 10 
             /if (${EndingVar}==1) /call AddComp "${Component[${i}]}" ${i} 
       /next i 
       /if (${EndingVar}==1) /call DoCombine 
       /if (${EndingVar}==1) /goto :Begin
 
    /delay ${Math.Calc[${DelayMult}*1]}
    /call ClosePacks
    /delay ${Math.Calc[${DelayMult}*1]}
    /target ${MerchantName}
    /face
    /nomodkey /click right target
    /delay ${Math.Calc[${DelayMult}*1]}
    /call OpenPacks
    /delay ${Math.Calc[${DelayMult}*2]}
    /call Sell ${ItemTo}
    /delay ${Math.Calc[${DelayMult}*1]}
    /nomodkey /notify MerchantWnd DoneButton leftmouseup
    /call ClosePacks

    /goto :start

    /return

Sub readIni(RecipeName) 
    /declare Container string 

    /echo Running ${RecipeName} recipe, which makes ${ItemTo}.

    /if (${Ini["jc.ini","${RecipeName}",-1,"NOTFOUND"].Equal["NOTFOUND"]}) { 
         /echo Recipe ${RecipeName} not found 
         /endmacro 
     } 

    /varset Container ${Ini[jc.ini,${RecipeName},Cont,Enviro]} 
 
    /if (${Container.Equal[Enviro]}) { 
         /varset PackCode Enviro 
    } else { 
         /varset PackCode ${FindItem[=${Container}].InvSlot} 
       
         /if (${PackCode.Equal[NULL]}) { 
            /echo Could not find container ${Container} 
            /varset EndingVar 2
            /return
         } 
         | pack1 = 22, ... , pack8 = 29 
         /varset PackCode pack${Math.Calc[${PackCode}-21].Int} 
    }  

    /call cleanPack "${Container}"

    /for i 1 to 10 
        /varset Component[${i}] ${Ini[jc.ini,${RecipeName},Comp${Math.Calc[${i}-1].Int},NOTFOUND]} 
    /next i 
    /return 

sub ClearCursor 
    :CursorLoop
      /autoinv 
|      /destroy	
    /delay ${Math.Calc[${DelayMult}*5]}
      /doevents 
      /if (${Cursor.ID}) /goto :CursorLoop
    /return 

sub DoCombine 
    :CombineLoop
      /combine ${PackCode} 
    /delay ${Math.Calc[${DelayMult}*1]}
      /if (${PackCode.Equal[Enviro]}) /delay 1s 
      /doevents 
      /if (${InvSlot[${PackCode}].Item.Items}) /goto :CombineLoop
      /delay ${Math.Calc[${DelayMult}*2]}
      /if (${Me.Skill[Jewelry Making]}>${OldSkill}) {
        /echo Your Jewelry Crafting Went Up!! It's now ${Me.Skill[Jewelry Making]}!
        /varset OldSkill ${Me.Skill[Jewelry Making]}
      }
    /return 

sub AddComp(CompName, PackSlot) 
   /if (${CompName.Equal[NOTFOUND]}) /return 

   /if (!${FindItem[=${CompName}].ID}) { 
      /echo Could not find ${CompName} in inventory 
      /beep 
      /varset EndingVar 2
      /return 
    } 

   :AddCompLoop
      /nomodkey /ctrl /itemnotify ${FindItem[=${CompName}].InvSlot} leftmouseup 

      /if (!${Cursor.ID}) { 
         /delay ${Math.Calc[${DelayMult}*1]}
         /goto :AddCompLoop
      } 

   /if (${PackCode.Equal[Enviro]}) { 
      /nomodkey /itemnotify ${InvSlot[enviro${PackSlot}]} leftmouseup 
   } else { 
      /nomodkey /itemnotify in ${PackCode} ${PackSlot} leftmouseup 
   }    
   /return 

Sub Event_CombineError 
    /varset EndingVar 2
/return

jc.ini file:

Code: Select all

[EL]
Cont=Jeweler's Kit
Comp0=electrum bar
Comp1=lapis lazuli

[EA]
Cont=Jeweler's Kit
Comp0=electrum bar
Comp1=amber

[GM]
Cont=Jeweler's Kit
Comp0=gold bar
Comp1=malachite

[GA]
Cont=Jeweler's Kit
Comp0=gold bar
Comp1=amber

[GT]
Cont=Jeweler's Kit
Comp0=gold bar
Comp1=topaz

[GO]
Cont=Jeweler's Kit
Comp0=gold bar
Comp1=opal

[GSR]
Cont=Jeweler's Kit
Comp0=gold bar
Comp1=star ruby

[GFE]
Cont=Jeweler's Kit
Comp0=gold bar
Comp1=fire emerald

[PLL]
Cont=Jeweler's Kit
Comp0=platinum bar
Comp1=lapis lazuli

[PJ]
Cont=Jeweler's Kit
Comp0=platinum bar
Comp1=jade

[SPN]
Cont=Jeweler's Kit
Comp0=platinum bar
Comp1=sapphire

[PRV]
Cont=Jeweler's Kit
Comp0=platinum bar
Comp1=ruby

[shadowman33]

ok, go ahead and flame me if you want to as this question does not belong here, but I have found no answers in game and of course sony is always so thurough with all their help LOL. Is tradeskilling past 250 level based or AA based? Or can anyone go past 250 since DON release?

[BrainDeath]

And flame me for replying. :)

Anyone can go past 250.

[Iamgman]

I'm curious, anyone else with salvage having trouble with this macro? Seems anytime I salvage something it would put an entire stack of gems or bars in the kit and pop up endless windows. Also when the mac was restarted it would sell all the bars and gems then rebuy them.

[Frank25]

fantum, thank you sooo much for that addition, worked like charm.

now the obbious question, is there a recipe to get to 300 using vendor bought items?

[VertiGOD]

Keep getting this as soon as im gonna buy something. Could not send Notification to merchant31 leftmouseup.
Any ideas ?

Thanks in advance.

[hot_love_bot]

i get couldnt not open sell.inc unable to add macro line.....
Any clues?

[drzoon]

i get couldnt not open sell.inc unable to add macro line.....
Any clues?

Read the whole thread. The part that seems to have stumped you is on the first page... actually its the first post on the first page....

[A_Druid_00]

So nice to the FNG. What's happened to this place!

[hot_love_bot]

thanks got the common dirrectory fixed ok now im having a problem when it tries to buy im geting could not send notification to merchant31 leftmouseup whats up with that?